Highlights Column when Intersect

[sunjam]

Hi Guys,

Please help,

when intersect to Column C-AP, highlight cell in column B.

My code here is when intersect to column C only, please edit my codes.

Big Thanks,

Range("B4:B2000").Interior.ColorIndex = xlNone
    If Not Intersect(Target, Range("C4:C2000")) Is Nothing Then
        Intersect(Target, Range("C4:C2000")).Offset(0, -1).Interior.Pattern = xlPatternLinearGradient
        Intersect(Target, Range("C4:C2000")).Offset(0, -1).Interior.Gradient.Degree = -45
        lngColor0 = Intersect(Target, Range("C4:C2000")).Offset(0, -1).Interior.Gradient.ColorStops(1).Color
        lngColor1 = Intersect(Target, Range("C4:C2000")).Offset(0, -1).Interior.Gradient.ColorStops(2).Color
        Intersect(Target, Range("C4:C2000")).Offset(0, -1).Interior.Gradient.ColorStops.Clear
        Set objColorStop = Intersect(Target, Range("C4:C2000")).Offset(0, -1).Interior.Gradient.ColorStops.Add(0)
        objColorStop.Color = lngColor0
        Set objColorStop = Intersect(Target, Range("C4:C2000")).Offset(0, -1).Interior.Gradient.ColorStops.Add(1)
        objColorStop.Color = RGB(0, 75, 0)

 

[jbeaucaire]

I'm thinking change all the instances of "C4:C2000" to "C4:AP2000".

 

[sunjam]

Thanks jbeaucaire

But the target is offset(0,-1)

if I intersect to column D, then Column C will highlight.

the code should highlight cells in bolumn B

this is my code below,

Range("B4:B2000").Interior.ColorIndex = xlNone
    If Not Intersect(Target, Range("C4:C2000")) Is Nothing Then
        Intersect(Target, Range("C4:C2000")).Offset(0, -1).Interior.Color = RGB(0, 75, 0)
    End If

Big Thanks,

 

[jbeaucaire]

Something like this perhaps:

Dim cell As Range

    If Not Intersect(Target, Range("C4:AP2000")) Is Nothing Then
        Range("B4:B2000").Interior.ColorIndex = xlNone
        Application.EnableEvents = False
        For Each cell In Intersect(Target, Range("C4:AP2000"))
            With Range("B" & cell.Row)
                .Interior.Pattern = xlPatternLinearGradient
                .Interior.Gradient.Degree = -45
                lngColor0 = .Interior.Gradient.ColorStops(1).Color
                lngColor1 = .Interior.Gradient.ColorStops(2).Color
                .Interior.Gradient.ColorStops.Clear
                Set objColorStop = .Interior.Gradient.ColorStops.Add(0)
                objColorStop.Color = lngColor0
                Set objColorStop = .Interior.Gradient.ColorStops.Add(1)
                objColorStop.Color = RGB(0, 75, 0)
            End With
        Next cell
        Application.EnableEvents = True
    End If

 

[sunjam]

WoW!

Man that's smooth!

I learned a lot from these codes.

Thanks man!

Cheers!