Horse Racing Combinations - Trifecta (Without Macro)

[jmcalabaza]

Hello Everyone!

Well, I am trying to gather all possible combinations for 10 horses for 3 place finishers. The 3 place finish is to illustrate a trifecta ticket. Example:

1-2-3
1-2-4
1-2-5
1-2-6
.
.
.
2-3-6
2-4-5
2-8-9


I understand for 10 horses, I should have a total of 720 combinations for a trifecta group. I really need help and I cannot figure out what formulas to use to achieve this. Also, I would like the formula to immediately toss out duplicates like (1-2-2, 2-2-4, etc.) in which that the #2 horse cannot finish in 2nd or 3rd place - only one place.

Thank you for your attention to this headache and I hope to hear from someone soon!

Jon

 

[StephenCrump]

Welcome to the Forum!

Much easier with VBA, but try these formulae, copied down the columns:

B2: =1+MOD(A2-1,NoHorses)
C2: =MOD(INT((A2-1)/NoHorses),NoHorses-1)+IF(1+MOD(INT((A2-1)/NoHorses),NoHorses-1)>=B2,1,0)+1
D2: =INT((A2-1)/NoHorses/(NoHorses-1))+1+IF(1+MOD(INT((A2-1)/NoHorses/(NoHorses-1)),NoHorses)>=MIN(B2:C2),IF(MOD(1+INT((A2-1)/NoHorses/(NoHorses-1)),NoHorses)+1>=MAX(B2:C2),2,1),0)

where NoHorses=10

The pattern will be easier to see if you Copy/Paste Values, and then sort on Column B/Column C.

Excel 2010

	A	B	C	D
1	Combinations	1st	2nd	3rd
2	1	1	2	3
3	2	2	1	3
4	3	3	1	2
5	4	4	1	2
6	5	5	1	2
7	6	6	1	2
8	7	7	1	2
9	8	8	1	2
10	9	9	1	2
11	10	10	1	2
12	11	1	3	2
13	12	2	3	1
14	13	3	2	1
15	14	4	2	1
16	15	5	2	1
17	….
18	720	10	9	8

<tbody>
</tbody>

Sheet1​

 

[jmcalabaza]

Stephen!

Thank you so much for this information. This helps a lot!

Have a great day Sir!

Jon