How can I exit a If statement loop unless just the selected cells are changed?

[cizwiz]

just wondering how i can exit a if statement loop

If (Range("A1") = "One") And (Range("A2") = "full") Then

  Rows("56:83").EntireRow.Hidden = True

  Range("A2") = "(Change Form Type)"

  Range("A3") = "One"

  Range("A1:J1").Select

Elseif (Range("A1") = "Two") And (Range("A2") = "Half") Then

  Rows("56:83").EntireRow.Hidden = False

  Range("A2") = "(Change Form Type)"

  Range("A3") = "Two"

  Range("A1:J1").Select

End If

I have this above however whenever i edit a cell that is not A1 or A2 the screen will flick and i assume it just runs the if statement again as the condition is still true is there a way i can stop this from happening unless A1 or A2 are changed

Tia Dan

 

[Fluff]

How are you running that?
Could you please supply the full code?

 

[cizwiz]

How are you running that?
Could you please supply the full code?

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, Range("A1:A2")) Is Nothing Then

    If (Range("A1") = "One") And (Range("A2") = "full") Then
        Rows("56:83").EntireRow.Hidden = True
        Range("A2") = "(Change Form Type)"
        Range("A3") = "One"
        Range("A1:J1").Select
    ElseIf (Range("A1") = "Two") And (Range("A2") = "Half") Then
        Rows("56:83").EntireRow.Hidden = False
        Range("A2") = "(Change Form Type)"
        Range("A3") = "Two"
        Range("A1:J1").Select
    End If

End If
End Sub

I've been making some edits to it but it doesn't work at all now doesn't error just doesn't do anything

 

[Norie]

Dan

That code will be triggered when you make a change anywhere on the sheet.

However unless that change is made in either A1 or A2 then the code won't actually do anything, it'll skip immediately to End Sub after the If.

 

[Fluff]

I'm surprised that it doesn't crash Xl, as you have written a permanent loop.
How about

Private Sub Worksheet_Change(ByVal Target As Range)
   If Target.CountLarge > 1 Then Exit Sub
   If Not Intersect(Target, Range("A1:A2")) Is Nothing Then
      On Error GoTo Xit
      Application.EnableEvents = False
      If Range("A1") = "One" And Range("A2") = "full" Then
         Rows("56:83").EntireRow.Hidden = True
         Range("A2") = "(Change Form Type)"
         Range("A3") = "One"
         Range("A1:J1").Select
      ElseIf Range("A1") = "Two" And Range("A2") = "Half" Then
         Rows("56:83").EntireRow.Hidden = False
         Range("A2") = "(Change Form Type)"
         Range("A3") = "Two"
         Range("A1:J1").Select
      End If
      Application.EnableEvents = True
   End If
Exit Sub
Xit:
Application.EnableEvents = True
MsgBox "Oops something went wrong"
End Sub

 

[Norie]

Fluff

Where's the permanent loop?

 

[Fluff]

Apologies, not a permanent loop, but will trigger again, if either If statement is true as A2 is being changed.