How can i remove a row if the dates are already included in dates on another row

[tonywatsonhelp]

Hi Everyone,
Ok so i have a problem, not got a clue how i can fix this so please help if you can
I download dates from a csv file,
Each Line has an ID, start date, and end date,
Now the problem I have is our systems are very old and quite a lot we get mutlpile lines for the same dates,
So for example I might get one which is for ID "7", 23 December 2019 to 3 January 2020
and another line for ID "7", 25 December2019 to 26 December 2019 but if I record the first dates then i get a doubling up of the second dates. so I need to remove the second dates.
So what i need a very clever macro that when run looks at the Info and does this
Column B is ID
Column D start date
Column E end date
for every row, if the ID is the same as this row then if the dates are with the dates of that row delete this row? (or something like this)
P.s there is space in L & M for any help rows that might be needed.

	ID	Start Date	End Date	what to do
	7	1 jan 2020	10 jan 2020	Keep this row!
	6	7 jan 2020	9 jan 2020	Keep this row!
	7	4 jan 2020	7 jan 2020	delete this row!	because this row has dates that are already withing dates in another row I dont need it!
	7	1 feb 2020	5 feb 2020	Keep this row!
	5	3 march 2020	5 march 2020	Keep this row!
	7	1 march 2020	5 march 2020	Keep this row!
	6	9 Jan 2020	9 jan 2020

 

[JGordon11]

In Power Query:

let
    Source = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
    ChangeType = Table.TransformColumnTypes(Source,{{"ID", Int64.Type}, {"Start Date", type date}, {"End Date", type date}}),
    AddIndex = Table.AddIndexColumn(ChangeType, "Index", 0, 1, Int64.Type),
    Group = Table.Group(AddIndex, {"ID"}, {{"All", each _, type table [ID=nullable number, Start Date=nullable date, End Date=nullable date]}}),
    AddKeep = Table.TransformColumns(Group, {{"All", (x)=> Table.AddColumn(x, "Keep", each List.Accumulate(List.Zip({x[Start Date],x[End Date]}),0,(s,c)=> 
        if [Start Date]>= c{0} and [End Date]<= c{1} then s+1 else s))}}),
    tcn = List.Skip(Table.ColumnNames(AddKeep[All]{0}),1),
    Expand = Table.ExpandTableColumn(AddKeep, "All", tcn, tcn),
    Filter = Table.SelectRows(Expand, each ([Keep] = 1)),
    Sort = Table.Sort(Filter,{{"Index", Order.Ascending}}),
    Result = Table.RemoveColumns(Sort,{"Index", "Keep"})
in
    Result

Book3
	A	B	C	D	E	F	G	H
1	ID	Start Date	End Date		ID	Start Date	End Date
2	7	1/1/2020	1/10/2020		7	1/1/2020	1/10/2020
3	6	1/7/2020	1/9/2020		6	1/7/2020	1/9/2020
4	7	1/4/2020	1/7/2020		7	2/1/2020	2/5/2020
5	7	2/1/2020	2/5/2020		5	3/3/2020	3/5/2020
6	5	3/3/2020	3/5/2020		7	3/1/2020	3/5/2020
7	7	3/1/2020	3/5/2020
8	6	1/9/2020	1/9/2020
9
Sheet1