How can I run this macro in multiple sheets simultaneously?

[JakeG]

I have a macro that I'm using to alphabetize an attendance list and then delete the 'Blank' rows (the cells actually return "" so, when sorted in descending order, they appear above the sorted list of names)

Below is the code, that seems to work perfectly - but it currently only runs in the sheet labelled "1", and I would like it to run in 8 sheets which are all labelled in numerical order, i.e. "1", "2", "3", "4", "5", "6", "7" and "8"

Sub SortPOSurnames()
'
' test
'

    ActiveWorkbook.Worksheets("1").Sort.SortFields.Clear
    ActiveWorkbook.Worksheets("1").Sort.SortFields.Add Key:=Range("D3:D42"), _
        SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
    With ActiveWorkbook.Worksheets("1").Sort
        .SetRange Range("A3:E42")
        .Header = xlGuess
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
    With ActiveSheet
    .AutoFilterMode = False
    With Range("d1", Range("d" & Rows.Count).End(xlUp))
        .AutoFilter 1, ""
        On Error Resume Next
        .Offset(2).SpecialCells(12).EntireRow.Delete
    End With
    .AutoFilterMode = False
End With



End Sub

 

[Joe4]

There are probably ways to simplify things a little, but here is a quick way to loop through sheets 1-8 and to run the code against each one:

Sub SortPOSurnames()
'
' test
    
    Dim s As Long

    For s = 1 To 8
        s.Activate
        ActiveWorkbook.Worksheets(s).Sort.SortFields.Clear
        ActiveWorkbook.Worksheets(s).Sort.SortFields.Add Key:=Range("D3:D42"), _
            SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        With ActiveWorkbook.Worksheets(s).Sort
            .SetRange Range("A3:E42")
            .Header = xlGuess
            .MatchCase = False
            .Orientation = xlTopToBottom
            .SortMethod = xlPinYin
            .Apply
        End With
        With ActiveSheet
            .AutoFilterMode = False
            With Range("d1", Range("d" & Rows.Count).End(xlUp))
                .AutoFilter 1, ""
                On Error Resume Next
                .Offset(2).SpecialCells(12).EntireRow.Delete
            End With
            .AutoFilterMode = False
        End With

End Sub

 

[dmt32]

Hi, welcome to forum

Untested but see if this update to your code will do what you want

Sub SortPOSurnames()
    Dim ws          As Worksheet
    Dim i           As Integer
    
    For i = 1 To 8
    
        Set ws = ActiveWorkbook.Worksheets(CStr(i))
        
        With ws
            
            With .Sort.SortFields
                .Clear
                .Add Key:=ws.Range("D3:D42"), SortOn:=xlSortOnValues, _
                                              Order:=xlAscending, _
                                              DataOption:=xlSortNormal
            End With
            
            With .Sort
                .SetRange ws.Range("A3:E42")
                .Header = xlGuess
                .MatchCase = False
                .Orientation = xlTopToBottom
                .SortMethod = xlPinYin
                .Apply
            End With
            
            .AutoFilterMode = False
            
            On Error Resume Next
            
            With .Range("d1", .Range("d" & .Rows.Count).End(xlUp))
                .AutoFilter 1, ""
                .Offset(2).SpecialCells(12).EntireRow.Delete
            End With
            .AutoFilterMode = False
        End With
        
        Set ws = Nothing
        On Error GoTo 0
    Next i
    
End Sub

Dave

 

[JakeG]

Hi, welcome to forum

Untested but see if this update to your code will do what you want..

Worked perfectly - thank you !

 

[dmt32]

Worked perfectly - thank you !

glad found solution that helped you - we appreciate the feedback

Dave

 

[JakeG]

There are probably ways to simplify things a little, but here is a quick way to loop through sheets 1-8 and to run the code against each one:

Apologies - didn't see this post, thanks very much !

 

[Joe4]

You are welcome.
Glad we were able to help.