how do i create worksheet change event only for a specific column i.e. q:q

[123amitjain]

the below codes are for entire sheet , but i just want to run the just for the entire column q
i just want to lock the column q for the entry just for one time.
how do i ?
i tried many times ....can anybody help me?





Private Sub Worksheet_Change(ByVal Target As Range)
Dim cl As Range


ActiveSheet.Unprotect

For Each cl In Target
If cl.Value <> "" Then
check = MsgBox("is this entry correct? this cell cant be edited after once entered", vbYesNo, "cell Lock Notification")
If check = vbYes Then
cl.Locked = True
Else
End If
End If
Next cl
ActiveSheet.Protect
End Sub

 

[Fluff]

Will you be changing one cell at a time, or multiple cells?

 

[123amitjain]

Will you be changing one cell at a time, or multiple cells?

one cell at a time

but for any cell within the entire column q

 

[Fluff]

Ok, how about

Private Sub Worksheet_Change(ByVal Target As Range)
   If Target.CountLarge > 1 Or Target.Value = "" Then Exit Sub
   If Not Intersect(Target, Range("Q:Q")) Is Nothing Then
      Me.Unprotect
      If MsgBox("is this entry correct? this cell cant be edited after once entered", vbYesNo, "cell Lock Notification") = vbYes Then
         Target.Locked = True
      End If
      Me.Protect
   End If
End Sub

 

[123amitjain]

Ok, how about

Private Sub Worksheet_Change(ByVal Target As Range)
   If Target.CountLarge > 1 Or Target.Value = "" Then Exit Sub
   If Not Intersect(Target, Range("Q:Q")) Is Nothing Then
      Me.Unprotect
      If MsgBox("is this entry correct? this cell cant be edited after once entered", vbYesNo, "cell Lock Notification") = vbYes Then
         Target.Locked = True
      End If
      Me.Protect
   End If
End Sub

wow
it works
i have been trying solving for this code from a long time .
but i couldn't do that perfectly
...
u r genius
hats off to you
thank you so much

 

[Fluff]

You're welcome & thanks for the feedback.