How to always capitalize a letter

[TSing3]

I have a file in which employees have to enter a simple Y or N for Yes/No. How can I make this always be capitalized even if they key it in lower case?

 

[Joe4]

Why not just use Data Validation on those cells, and limit them to choosing from the list of "Y" and "N" that you set up?

Another option would be to use VBA to automatically change all entries they make it certain cells capitalized.

 

[TSing3]

Didn’t even think of data validation. Duh! I’ll just do that.

 

[Joe4]

Didn’t even think of data validation. Duh! I’ll just do that.

The only caveat is if they were to use Copy/Paste to copy from another cell, it would overwrite the Data Validation.

If you wanted to go the VBA route, here is a robust code that will not only convert the lower case "y" and "n" to upper case, but also prevent anything else from being entered into these cells.
This code must be placed in the Sheet module that you want to apply it to (you can get there by going to the sheet, right-clicking on the sheet tab name at the bottom of the screen, selecting "View Code", and pasting this code in the VB Editor window that pops up).

Private Sub Worksheet_Change(ByVal Target As Range)

    Dim rng As Range
    Dim cell As Range
    
'   Apply this to column B
    Set rng = Intersect(Target, Columns("B:B"))
    
'   Exit sub if no updates in desired column
    If rng Is Nothing Then Exit Sub
    
    Application.EnableEvents = False
    
'   Loop through each cell
    For Each cell In rng
'       Skip line 1
        If cell.Row > 1 Then
'           Check to see if they entered "Y" or "N"
            If UCase(cell) = "Y" Or UCase(cell) = "N" Then
                cell = UCase(cell)
            Else
'               Check for any other entry
                If Len(cell) > 0 Then
                    cell.ClearContents
                    MsgBox "You entered an invalid entry", vbOKOnly, "TRY AGAIN!"
                End If
            End If
        End If
    Next cell
    
    Application.EnableEvents = True
    
End Sub

To change the range you wish to apply it to, just change the part below in red to the range you want to apply it to:

    Set rng = Intersect(Target, Columns("B:B"))

Also note this line here, set to skip the first line (assumed header row):

'       Skip line 1
        If cell.Row > 1 Then

If you have other rows at the top to skip that haven't been accounted for in the initial range declaration, just change the number after the greater than sign to reflect the last row number you want to exclude.