How to combine multiple change events VBA

[Empirer]

Hi all,

Currently I try to set multiple change events criteria on one worksheet. However, only the first criteria with range (I:I) seems to be working.

Private Sub Worksheet_Change(ByVal Target As Range)
Dim A As Range: Set A = Range("I:I")
Dim v As String
If Intersect(Target, A) Is Nothing Then
Exit Sub

Application.EnableEvents = False
v = Target.Value
If v <> "" Then Target.Offset(0, -8) = Now()
If v = "" Then Target.Offset(0, -8) = ""
Application.EnableEvents = True
End If

Dim B As Range: Set B = Range("M:M")
Dim w As String
If Intersect(Target, B) Is Nothing Then
Exit Sub
Application.EnableEvents = False
w = Target.Value
If w = "Completed" Then Target.Offset(0, -1) = Now()
If w = "" Then Target.Offset(0, -1) = ""
Application.EnableEvents = True
End If

 

[Fluff]

Hi & welcome to MrExcel.
How about

Private Sub Worksheet_Change(ByVal Target As Range)
   If Not Intersect(Target, Range("I:I")) Is Nothing Then
      If Target <> "" Then
         Target.Offset(0, -8) = Now
      Else
         Target.Offset(0, -8) = ""
      End If
   ElseIf Not Intersect(Target, Range("M:M")) Is Nothing Then
      If Target = "Completed" Then
         Target.Offset(0, -1) = Now
      ElseIf Target = "" Then
         Target.Offset(0, -1) = ""
      End If
   End If
End Sub

 

[Empirer]

Thanks, the code works, but just to confirm I want the date stamps to not change over time.
Don't I have to add the Application.EnableEvents part?

 

[Fluff]

With that code there is no need to disable events, as the code is changing cells outside of columns I & M.
The date/time stamps will not change unless you change a value in either column I or M.