How to copy and paste rows into alternate starting columns

[Jiriyanu]

Hi all,

I'm trying to prepare data for import and the software requires me to use two sets of headers in order to import 2 sets of data into one page (2 forms in one page, think tax forms). Problem is I have clients that have over 50 people that need to each have forms.

Basically, I'd like to have all odd rows (A7:Z7, A9:Z9, etc) of sheet A to be pasted starting at A2 of sheet B, and all even rows (A8:Z8, A10:Z10, etc) to be pasted starting at AA2 of sheet B.

Honestly I'm not sure where to start with this coding. I'm still very much a beginner.

Any and all help is appreciated. Thank you!

 

[Fluff]

How about

Sub Jiriyanu()
   Dim UsdRws As Long
   Dim Orws As Variant, Erws As Variant, Oary As Variant, Eary As Variant
   
   With Sheets("Sheet1")
      UsdRws = .Range("A" & Rows.Count).End(xlUp).Row
   
      Orws = Application.Transpose(Filter(Evaluate("Transpose(if(isodd(row(7:" & UsdRws & ")),row(7:" & UsdRws & "),""x""))"), "x", False))
      Erws = Application.Transpose(Filter(Evaluate("Transpose(if(iseven(row(7:" & UsdRws & ")),row(7:" & UsdRws & "),""x""))"), "x", False))
      Oary = Application.Index(.Range("A1:Z" & UsdRws).Value, Orws, Evaluate("column(A:Z)"))
      Eary = Application.Index(.Range("A1:Z" & UsdRws).Value, Erws, Evaluate("column(A:Z)"))
   End With
   With Sheets("Sheet2")
      .Range("A2").Resize(UBound(Oary), 26).Value = Oary
      .Range("AA2").Resize(UBound(Eary), 26).Value = Eary
   End With
End Sub

 

[Jiriyanu]

How about

Sub Jiriyanu()
   Dim UsdRws As Long
   Dim Orws As Variant, Erws As Variant, Oary As Variant, Eary As Variant
  
   With Sheets("Sheet1")
      UsdRws = .Range("A" & Rows.Count).End(xlUp).Row
  
      Orws = Application.Transpose(Filter(Evaluate("Transpose(if(isodd(row(7:" & UsdRws & ")),row(7:" & UsdRws & "),""x""))"), "x", False))
      Erws = Application.Transpose(Filter(Evaluate("Transpose(if(iseven(row(7:" & UsdRws & ")),row(7:" & UsdRws & "),""x""))"), "x", False))
      Oary = Application.Index(.Range("A1:Z" & UsdRws).Value, Orws, Evaluate("column(A:Z)"))
      Eary = Application.Index(.Range("A1:Z" & UsdRws).Value, Erws, Evaluate("column(A:Z)"))
   End With
   With Sheets("Sheet2")
      .Range("A2").Resize(UBound(Oary), 26).Value = Oary
      .Range("AA2").Resize(UBound(Eary), 26).Value = Eary
   End With
End Sub

Thank you so much, Fluff! This worked perfectly with no errors. ?

 

[Fluff]

You're welcome & thanks for the feedback.