How to copy data to new template from list after new workbook had been created

[mrkdx]

Hello I not sure how to resolve this. I am new to VBA.
I have a template workbook ( named "Template") that I copy multiple times and rename from a list ( name " list " from cell A2 downwards)

the second step which is where I need help ,
is to have the new worksheet template filled with the information from List

B2 downwards from list to A1 on new copied and named template
C2 downwards from list to G1 on new copied and named template
D1 downwards from list to M1 on new copied and named template


Any help would be greatly appreciated.

List

Template

Below is is the VBA that I have been using to create my new workbook template and rename them from list

Sub SaveMasterAs()

Dim wb As Workbook

Dim rNames As Range, c As Range, r As Range

Set rNames = Worksheets("Sheet1").Range("A2", Worksheets("Sheet1").Range("A2").End(xlDown))

Set wb = Workbooks.Open(ThisWorkbook.Path & "\Template.xlsx")

For Each c In rNames

With wb

.SaveAs Filename:=ThisWorkbook.Path & "\Template Copy\" & c.Value & ".xlsx", FileFormat:=xlOpenXMLWorkbook, CreateBackup:=False

End With

Set wb = ActiveWorkbook

Next c

wb.Close

End Sub

 

[Fluff]

Hi & welcome to MrExcel.
Does you template workbook only have one sheet?

 

[mrkdx]

Hi & welcome to MrExcel.
Does you template workbook only have one sheet?

Yes it does.

 

[Fluff]

Ok, how about

Sub mrkdx()
   Dim wb As Workbook
   Dim rNames As Range, c As Range, r As Range

   With Worksheets("Sheet1")
      Set rNames = .Range("A2", .Range("A" & Rows.count).End(xlUp))
   End With
   Set wb = Workbooks.Open(ThisWorkbook.path & "\Template.xlsx")
   For Each c In rNames
      With wb
         .Sheets(1).Range("A1").Value = c.Offset(, 1).Value
         .Sheets(1).Range("G1").Value = c.Offset(, 2).Value
         .Sheets(1).Range("M1").Value = c.Offset(, 3).Value
         .SaveAs ThisWorkbook.path & "\Template Copy\" & c.Value & ".xlsx", 51
      End With
   Next c
   wb.Close
End Sub

 

[mrkdx]

Ok, how about

Sub mrkdx()
   Dim wb As Workbook
   Dim rNames As Range, c As Range, r As Range

   With Worksheets("Sheet1")
      Set rNames = .Range("A2", .Range("A" & Rows.count).End(xlUp))
   End With
   Set wb = Workbooks.Open(ThisWorkbook.path & "\Template.xlsx")
   For Each c In rNames
      With wb
         .Sheets(1).Range("A1").Value = c.Offset(, 1).Value
         .Sheets(1).Range("G1").Value = c.Offset(, 2).Value
         .Sheets(1).Range("M1").Value = c.Offset(, 3).Value
         .SaveAs ThisWorkbook.path & "\Template Copy\" & c.Value & ".xlsx", 51
      End With
   Next c
   wb.Close
End Sub

Thank you very much Fluff that worked..

 

[Fluff]

You're welcome & thanks for the feedback.