How to delete 4 lines from each workbook in a specific folder-vba code required

[kishorvimal]

Hi,

Can anyone help me with vba code to delete starting 4 lines in each workbook in a folder.

Thanks in advance
vimal

 

[Damon Ostrander]

Hi vimal,

Here is code that deletes the first 4 rows of each worksheet of each Excel workbook in the current working folder.

Sub OpenAll()

'  This macro opens all files in the working (default) directory,
'  one at a time, then loops through all worksheets in the workbook
'  deleting the first four rows, and then closes each file.

   Dim Filename      As String
   Dim GoAhead       As Variant
   Dim WS            As Worksheet
   
   'Look for all files ending with .xls
   'Can include entire path if desired. This example assumes working
   'directory so no path specified.
   Filename = Dir("*.xls*")
   
   GoAhead = MsgBox("This macro will delete the first 4 rows of every workbook" & vbLf & _
                    "in " & Application.DefaultFilePath & ", starting with: " & vbLf & _
                    Filename & ". Are you sure?", vbYesNo, "Important Warning")
   If GoAhead = vbNo Then Exit Sub
   
   Application.DisplayAlerts = False
   
   Do While Filename <> ""
   
      Workbooks.Open Filename
      Application.StatusBar = Filename & " opened."
      
      For Each WS In Worksheets
         WS.Rows("1:4").Delete
      Next WS
      
      ActiveWorkbook.Close True
      Application.StatusBar = Filename & " closed."
      
      'read next filename
      Filename = Dir()
   Loop
   
   Application.DisplayAlerts = False
   Application.StatusBar = False

End Sub

To set the current working folder to the folder you want to process you can simply use File > Open, then use the Open dialog to browse to the folder you want, then click the Cancel button, i.e., you don't have to actually open a file in that folder to set it as the working folder.

Please use this macro with caution. It would be very easy to accidentally apply it to the wrong folder and wipe out the first four rows of a lot of worksheets you didn't intend to modify. It is for this reason that I put an "Are you sure?" popup in the macro.

Keep Excelling.

Damon