How to fill in blank rows in mutiple columns?

[Ann99]

Hi,
Last week I found a thread with VBA that enabled blank rows below a value to be filled in with that value until the next value, then the rows below were filled in with the second value and so on.

It worked in Column A only. How can this work in all columns that need the same treatment, A, B, C, etc.?

This is the VBA from the thread that I used:

Sub FillInFromRowAbove1()

With Range("A2", Cells(Rows.Count, "B").End(xlUp).Offset(, -1))
.SpecialCells(xlCellTypeBlanks).FormulaR1C1 = "=r[-1]c"
.Value = .Value
End With
End Sub

Thanks, Ann

 

[VoG]

Try

Sub FillInFromRowAbove1()
Dim LR As Long
LR = Cells.Find(What:="*", SearchDirection:=xlPrevious, SearchOrder:=xlByRows).Row
With Range("A2:C" & LR)
    .SpecialCells(xlCellTypeBlanks).FormulaR1C1 = "=R[-1]C"
    .Value = .Value
End With
End Sub

 

[Ann99]

Peter, The macro worked awesomely well! Thanks so much! Ann

 

[Myproblem]

Try

Sub FillInFromRowAbove1()
Dim LR As Long
LR = Cells.Find(What:="*", SearchDirection:=xlPrevious, SearchOrder:=xlByRows).Row
With Range("A2:C" & LR)
    .SpecialCells(xlCellTypeBlanks).FormulaR1C1 = "=R[-1]C"
    .Value = .Value
End With
End Sub

it is great macro, i would like to ask how would be this macro should be modife in the way that with message box it ask you which column is the the last right column (i want this vba code to make it in private.xls and it would be great stuff making it)
thx in advance

 

[VoG]

Maybe this - LC finds the last column.

Sub FillInFromRowAbove1()
Dim LR As Long, LC As Long
LR = Cells.Find(What:="*", SearchDirection:=xlPrevious, SearchOrder:=xlByRows).Row
LC = Cells.Find(What:="*", SearchDirection:=xlPrevious, SearchOrder:=xlByColumns).Column
With Range(Cells(2, 1), Cells(LR, LC))
    .SpecialCells(xlCellTypeBlanks).FormulaR1C1 = "=R[-1]C"
    .Value = .Value
End With
End Sub

 

[Myproblem]

thx man,
i just modify it to be placed into module so it can be actived in any active sheet (due need to be called from private), thx again my timesaver:
Sub FillInFromRowAbove1()
With ActiveSheet
Dim LR As Long, LC As Long
LR = Cells.Find(What:="*", SearchDirection:=xlPrevious, SearchOrder:=xlByRows).Row
LC = Cells.Find(What:="*", SearchDirection:=xlPrevious, SearchOrder:=xlByColumns).Column
With Range(Cells(2, 1), Cells(LR, LC))
.SpecialCells(xlCellTypeBlanks).FormulaR1C1 = "=R[-1]C"
.Value = .Value
End With
End With
End Sub

 

[VoG]

Then it should be

Sub FillInFromRowAbove1()
Dim LR As Long, LC As Long
With ActiveSheet
    LR = .Cells.Find(What:="*", SearchDirection:=xlPrevious, SearchOrder:=xlByRows).Row
    LC = .Cells.Find(What:="*", SearchDirection:=xlPrevious, SearchOrder:=xlByColumns).Column
    With .Range(.Cells(2, 1), .Cells(LR, LC))
        .SpecialCells(xlCellTypeBlanks).FormulaR1C1 = "=R[-1]C"
        .Value = .Value
    End With
End With
End Sub