If Cell Left of Selected Cell is Blank, then Sum Offset of (,-3)+(,-2) else (,-1)

[MikeL]

Hello,
I have selected last nonblank cell in Row 3.
'Range End Method last blank cell in Row 3
Cells(3, Columns.Count).End(xlToLeft).Offset(, 1).Select

Would like If Then with logic like:
If Offset(,-1) is 0 Then Sum (offset(,-3)+ (,-2) else just Offset(,-1)

How to write this in VBA?

 

[Crystalyzer]

Sub LastBlankCellToLeft()
    Dim c As Range
    'Range End Method last blank cell in Row 3
    Set c = Cells(3, Columns.Count).End(xlToLeft).Offset(0, 1)
    
    If c.Offset(0, -1).Value = 0 Then
        c.Formula2R1C1 = "=R[0]C[-3]+R[0]C[-2]"
    Else
        c.Formula2R1C1 = "=R[0]C[-1]"
    End If
End Sub

 

[footoo]

Sub v()
With Cells(3, Columns.Count).End(xlToLeft).Offset(, 1)
    If .Offset(, -1) <> 0 Then .Value = .Offset(, -1) Else .Value = .Offset(, -3) + .Offset(, -2)
End With
End Sub

 

[MikeL]

Sub LastBlankCellToLeft()
    Dim c As Range
    'Range End Method last blank cell in Row 3
    Set c = Cells(3, Columns.Count).End(xlToLeft).Offset(0, 1)
   
    If c.Offset(0, -1).Value = 0 Then
        c.Formula2R1C1 = "=R[0]C[-3]+R[0]C[-2]"
    Else
        c.Formula2R1C1 = "=R[0]C[-1]"
    End If
End Sub

Thanks I got error 438 on this line c.Formula2R1C1 = "=R[0]C[-1]"

 

[Crystalyzer]

Thanks I got error 438 on this line c.Formula2R1C1 = "=R[0]C[-1]"

is the empty cell by chance in column A?

 

[MikeL]

Sub v()
With Cells(3, Columns.Count).End(xlToLeft).Offset(, 1)
    If .Offset(, -1) <> 0 Then .Value = .Offset(, -1) Else .Value = .Offset(, -3) + .Offset(, -2)
End With
End Sub

Thanks - this works. How do I autofill down?

 

[MikeL]

is the empty cell by chance in column A?

Yes, also how can I autofill down

 

[footoo]

Sub v()
Dim col&, lr&, rng As Range
col = Cells.Find(What:="*", LookIn:=xlValues, SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Column + 1
lr = Cells.Find(What:="*", LookIn:=xlValues, SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
Set rng = Range(Cells(3, col), Cells(lr, col))
rng.FormulaR1C1 = "=IF(RC[-1]=0,RC[-3]+RC[-2],RC[-1])"
rng = rng.Value 'Omit this line if you want to keep the formula
End Sub

 

[MikeL]

Sub v()
Dim col&, lr&, rng As Range
col = Cells.Find(What:="*", LookIn:=xlValues, SearchOrder:=xlByColumns, SearchDirection:=xlPrevious).Column + 1
lr = Cells.Find(What:="*", LookIn:=xlValues, SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
Set rng = Range(Cells(3, col), Cells(lr, col))
rng.FormulaR1C1 = "=IF(RC[-1]=0,RC[-3]+RC[-2],RC[-1])"
rng = rng.Value 'Omit this line if you want to keep the formula
End Sub

Thanks