If False Do Nothing

[Winchester1894]

How do you do Friends,

I have a large data set and I would like to search for a keyword and update the cell 5 columns over from it.
This is what I have so far:

Sub Find_and_Write()

Dim X As Variant, F As Range
X = Application.InputBox("Enter Value")
If TypeName(X) = "Boolean" Then Exit Sub
Set F = Columns("C").Find(what:="C-1290", LookIn:=xlValues, lookat:=xlWhole)
If Not F Is Nothing Then F.Offset(, 5).Value = X


End Sub

This code works but only for the first instance of the desired change. I would like it to run down the entire column and perform the edit. I tried adding a for loop but it only looped changing the first instance. What am I missing to make it run for the entirety of the column?

Any help appreciated, thank you.

 

[Leith Ross]

Hello Winchester1894,

Here is the updated code...

Sub Find_and_Write()


    Dim F           As Range
    Dim FirstFind   As String
    Dim X           As Variant


        X = Application.InputBox("Enter Value")
        If TypeName(X) = "Boolean" Then Exit Sub
        
        Set F = Columns("C").Find(what:="C-1290", LookIn:=xlValues, lookat:=xlWhole)
        If F Is Nothing Then Exit Sub
        
        FirstFind = F.Address
        
        Do
            F.Offset(0, 5) = X
            Set F = Columns("C").FindNext(F)
            If F Is Nothing Then Exit Do
            If F.Address = FirstFind Then Exit Do
        Loop


End Sub

 

[Winchester1894]

Much appreciated Mr. Ross. You are a scholar and a gentleman.

 

[Fluff]

Hi & welcome to the board
Another option

Sub Find_and_Write()

Dim X As Variant
X = Application.InputBox("Enter Value")
If TypeName(X) = "Boolean" Or Len(X) = 0 Then Exit Sub
With Range("H2", Range("C" & Rows.Count).End(xlUp).Offset(, 5))
   .Value = Evaluate("if(" & .Offset(, -5).Address & "=""AL2 2EJ""," & Chr(34) & X & Chr(34) & "," & .Address & ")")
End With

End Sub

 

[Leith Ross]

Hello Winchester1894,

You are most welcome. Glad I could be of assistance.