=if(iserror

[j4ymf]

hello

can i change this code so that if there is an error it changes it to somthing like this code
=IF(ISERROR($G$17/$H$17),"- - -",$G$17/$H$17)

thanks jason

=SUMPRODUCT(--($E$31:$E$475="MABF")*($O$31:$O$475="RED"),$H$31:$H$475)

 

[martindwilson]

i cant see how you get an error anyway unless there is an error in one of the ranges
and fyi the -- is unnecessary if you are using *
=SUMPRODUCT(($E$31:$E$475="MABF")*($O$31:$O$475="RED"),$H$31:$H$475)
or use
=SUMPRODUCT(--($E$31:$E$475="MABF"),--($O$31:$O$475="RED"),$H$31:$H$475)

 

[j4ymf]

Hello martindwilson

Thanks for your reply

the reason i get errors #N/A is some time i have empty rows and not always will my query go down to 475

thanks jason

 

[martindwilson]

if you put that formula in a cell on a blank sheet you get 0 not n/a,

 

[Jonmo1]

The basic syntax of If(Iserror is

=IF(ISERROR(calc),"do this instead of error",calc)

replace calc with the calculation you want to test for an error.
replace "do this instead of error" with the value you want returned instead of the error.

The calculation you want to test for an error is
SUMPRODUCT(--($E$31:$E$475="MABF")*($O$31:$O$475="RED"),$H$31:$H$475)

So it becomes
=IF(ISERROR(SUMPRODUCT(--($E$31:$E$475="MABF")*($O$31:$O$475="RED"),$H$31:$H$475)),"do this instead of error",SUMPRODUCT(--($E$31:$E$475="MABF")*($O$31:$O$475="RED"),$H$31:$H$475))

If you have XL2007+ it's muich easier with IFERROR
=IFERROR(calc,"do this instead of error")
=IFERROR(SUMPRODUCT(--($E$31:$E$475="MABF")*($O$31:$O$475="RED"),$H$31:$H$475),"do this instead of error")