If statement question.

[Tami]

I need to run a formula that will look and see if data is greater then, equal to or lesser then a condition and if it is then multiply a cell by another cell but I'm having problems with it.

Here is the forumla that I've written, can anyone please assist.

=IF(H27<=4,D27*0%,IF(H27>=5<=9,D27*3%,IF(H27>=10<=14,D27*4%,IF(H27>=15<=19,D27*6%,IF(H27>=20<=24,D27*7%,IF(H27>=25,D27*8%))))))

This forumla is returning FALSE into the cell.

Info for the cells

H27=15, D27=$28,912.00 - so the calculation should be calculating that H27 being 15, should take the $28,912.00 and multiply that figure by 6%.

I hope I've been clear enough on my example.


Thanks in advance for any help.
Tami

 

[Aladin Akyurek]

Try

=D27*VLOOKUP(H27,{0,0;5,0.03;10,0.04;15,0.06;20,0.07;25,0.08},2,0)

instead.

 

[Asala42]

=IF(H27<=4,D27*0%,IF(H27>=5<=9,D27*3%,IF(H27>=10<=14,D27*4%,IF(H27>=15<=19,D27*6%,IF(H27>=20<=24,D27*7%,IF(H27>=25,D27*8%))))))

This should work.

=IF(H27<=4,D27*0%,IF(H27<=9,D27*3%,IF(H27<=14,D27*4%,IF(H27<=19,D27*6%,IF(H27<=24,D27*7%,IF(H27,D27*8%))))))

I think it was choking on statements like:
H27>=20<=24

You could have also replaced statements like that to:
AND(H27>=20,H27<=24)

HTH

 

[Barrie Davidson]

Or you could try:

=IF(H27<=4,D27*0%,IF(H27<=9,D27*3%,IF(H27<=14,D27*4%,IF(H27<=19,D27*6%,IF(H27<=24,D27*7%,D27*8%)))))

Regards,

 

[Tami]

Thanks!!! It worked great, I was thinking it would accept the <=,>= as two separate statements, not realizing I had to separate them. Friday afternoon, I should have expected that.

Thanks again!!!

 

[Chas17]

Aladin's is the one to use, use the Vlookup, the others work fine but you could place the Percents in cells and reference the cells, then if the percents change you only have to change one cell, not all the formulas.