If/then copy adjacent and paste value to adjacent on two different sheets

[jerry1992]

Thanks for your help in advance I'm still very new to vba.

If I have data on sheet3 that I want to copy and paste in a specific cell on sheet1 how would I go about doing that for a specific
area of cells

Basically I need this.

if any cell in A2-33 on sheet1 equals any cell in E2-400 on sheet3 then copy whatever is in the cell next to cell E?(sheet3) in cell F?(sheet3)
and paste the value into the cell next to A?(sheet1) in cell B?(sheet1)

? being the row number where they match.

It has to be a value paste as well

so I guess something like this?

E?(sheet3)=A?(sheet1) so copy F?(sheet3) and paste value in B?(sheet1) .... but like in VBA

Thanks so much. I usually just search forums where someone is trying to do something similar and adjust their code to work for my workbook but I'm having difficulty finding something similar to this.



Is this even possible?

 

[Fluff]

Any particular reason why you want VBA? This can be done with a simple vlookup formula.

 

[jerry1992]

Any particular reason why you want VBA? This can be done with a simple vlookup formula.

It is a macro I will end up attaching to a button with other macros to use in specific instances. At other times I will be pressing other buttons to clear the same cells and get different information to paste into the same cells I intend to use this for.

 

[Fluff]

Ok, how about

Sub jerry()
   Dim Cl As Range
   Dim Dic As Object
   
   Set Dic = CreateObject("scripting.dictionary")
   With Sheets("Sheet3")
      For Each Cl In .Range("E2", .Range("E" & Rows.Count).End(xlUp))
         Dic(Cl.Value) = Cl.Offset(, 1).Value
      Next Cl
   End With
   With Sheets("Sheet1")
      For Each Cl In .Range("A2", .Range("A" & Rows.Count).End(xlUp))
         If Dic.Exists(Cl.Value) Then Cl.Offset(, 1).Value = Dic(Cl.Value)
      Next Cl
   End With
End Sub

 

[jerry1992]

That worked flawlessly! Thank you so much!

 

[Fluff]

You're welcome & thanks for the feedback.