IFERROR Formula help

bwlytkr

Board Regular
Joined
Jun 8, 2012
Messages
70
I could use some help with this formula. First time using an IFERROR formula so not sure what I'm doing wrong. I keep getting a "too few arguments error". Any help would be appreciated.


=IFERROR(INDEX('[TICKET STEP LONG.xlsx]RAW_COMPLETIONS'!$B:$B,MATCH(G2,'[TICKET STEP LONG.xlsx]RAW_COMPLETIONS'!$A:$A,0)),IF(LEN(AM2)=8,AM2,IFERROR(INDEX('[WLS07.xlsx]WLS07'!$b:$b,MATCH(Am2,'[WLS07.xlsx]WLS07'!$a:$a,0)),IFERROR(INDEX('[wls07.xlsx]MAIN CITY'!$d:$d,MATCH(Ai2,'[wls07.xlsx]MAIN CITY'!$B:$B,0)))
 

Scott T

Well-known Member
Joined
Dec 14, 2016
Messages
2,556
Office Version
365, 2016
Platform
Windows
Your last iferror does not have a value-if-error that is the value to return if there is an error
 

bwlytkr

Board Regular
Joined
Jun 8, 2012
Messages
70
Not sure I follow. Isn't the last iferror telling me if column d in main city matches ai2 to populate the corresponding cell in column b
 

Special-K99

Well-known Member
Joined
Nov 7, 2006
Messages
8,301
Format of IFERROR

IFERROR(formula, result if error)

Wheres your "result if error" in that formula?

All you have are IFERROR(INDEX(...MATCH(...)) , should be something here )s
 
Last edited:

Scott T

Well-known Member
Joined
Dec 14, 2016
Messages
2,556
Office Version
365, 2016
Platform
Windows
IFERROR(value, value_if_error)
If value does NOT return an error then the result of value is displayed.
If value does return an error then value_if_error is returned.

for example
=IFERROR(INDEX(B1:B7,MATCH("bob",A1:A7,0)),"not found")
If index match returns an error because bob is not found then instead of returning a N/A error the formula returns "not found"


The text in red is the value augment.
The text in blue is what you are missing.
If the index match in red is an error then the zero is what is returned. You should change that to what you want to return if VALUE is an error.

=IFERROR(INDEX('[TICKET STEP LONG.xlsx]RAW_COMPLETIONS'!$B:$B,MATCH(G2,'[TICKET STEP LONG.xlsx]RAW_COMPLETIONS'!$A:$A,0)),IF(LEN(AM2)=8,AM2,IFERROR(INDEX('[WLS07.xlsx]WLS07'!$b:$b,MATCH(Am2,'[WLS07.xlsx]WLS07'!$a:$a,0)),IFERROR(INDEX('[wls07.xlsx]MAIN CITY'!$d:$d,MATCH(Ai2,'[wls07.xlsx]MAIN CITY'!$B:$B,0)),0))))
 

Forum statistics

Threads
1,077,851
Messages
5,336,753
Members
399,100
Latest member
darcob

Some videos you may like

This Week's Hot Topics

Top