Importing Multiple csv files

[anuradhagrewal]

Hello
I have an excel sheet in which I regularly need to import data that is in *.csv format.
I would be very grateful if someone can provide me a VB code where I can import in a query all these csv files into the existing Excel file.
I have been able to find code where the codes *.csv files are imported but with the csv file name.
I want that the file name, this I want to be replaced by a number like 1,2,3 etc depending on the number of csv files imported.

Can anyone please help me.

Much Obliged

Regards

Anu

 

[maabadi]

Why you don't use power query, You need only refresh when new file added to folder
Guide on this Links:
Import all CSV files in a folder into Excel

How to combine / import multiple csv files into multiple​

14 - Combine CSV Files (or Text Files) in a Folder​

در دیدئو ببینید
https://www.extendoffice.com/documents/excel/3230-excel-import-multiple-csv-files.html

 

[anuradhagrewal]

Thanks but I am using MS Excel 2007.
Also I am aware of this link

How to combine / import multiple csv files into multiple​

In this the worksheet name is the file name of the CSV file which does not help.
If there is VB script where I can get a genric sheet 1 sheet 2 sheet 3 for all the csv files imported that would help.

 

[maabadi]

Please Upload Minimum example of 2 CSV file to work on it. Upload at free hosting site e.g. www.dropbox.com or GoogleDrive or OneDrive & insert link here.

 

[maabadi]

Try this:

Sub CombineCsvFiles()
    Dim xFilesToOpen As Variant, I As Integer, xWb As Workbook, xTempWb As Workbook
    Dim xDelimiter As String, fileName As String
    Dim xScreen As Boolean
    On Error GoTo ErrHandler
    xScreen = Application.ScreenUpdating
    Application.ScreenUpdating = False
    xDelimiter = "|"
    xFilesToOpen = Application.GetOpenFilename("Text Files (*.csv), *.csv", , , , True)
    If TypeName(xFilesToOpen) = "Boolean" Then
        MsgBox "No files were selected"
        GoTo ExitHandler
    End If
    I = 1
    fileName = xFilesToOpen(I)
    Debug.Print fileName
    Set xTempWb = Workbooks.Open(xFilesToOpen(I))
    xTempWb.Sheets(1).Copy
    Set xWb = Application.ActiveWorkbook
    xTempWb.Close False
    Do While I < UBound(xFilesToOpen)
        I = I + 1
        Set xTempWb = Workbooks.Open(xFilesToOpen(I))
        xTempWb.Sheets(1).Move , xWb.Sheets(xWb.Sheets.Count)
    Loop
ExitHandler:
    Application.ScreenUpdating = xScreen
    Set xWb = Nothing
    Set xTempWb = Nothing
    Exit Sub
ErrHandler:
    MsgBox Err.Description
    Resume ExitHandler
End Sub

 

[anuradhagrewal]

Try this:

Sub CombineCsvFiles()
    Dim xFilesToOpen As Variant, I As Integer, xWb As Workbook, xTempWb As Workbook
    Dim xDelimiter As String, fileName As String
    Dim xScreen As Boolean
    On Error GoTo ErrHandler
    xScreen = Application.ScreenUpdating
    Application.ScreenUpdating = False
    xDelimiter = "|"
    xFilesToOpen = Application.GetOpenFilename("Text Files (*.csv), *.csv", , , , True)
    If TypeName(xFilesToOpen) = "Boolean" Then
        MsgBox "No files were selected"
        GoTo ExitHandler
    End If
    I = 1
    fileName = xFilesToOpen(I)
    Debug.Print fileName
    Set xTempWb = Workbooks.Open(xFilesToOpen(I))
    xTempWb.Sheets(1).Copy
    Set xWb = Application.ActiveWorkbook
    xTempWb.Close False
    Do While I < UBound(xFilesToOpen)
        I = I + 1
        Set xTempWb = Workbooks.Open(xFilesToOpen(I))
        xTempWb.Sheets(1).Move , xWb.Sheets(xWb.Sheets.Count)
    Loop
ExitHandler:
    Application.ScreenUpdating = xScreen
    Set xWb = Nothing
    Set xTempWb = Nothing
    Exit Sub
ErrHandler:
    MsgBox Err.Description
    Resume ExitHandler
End Sub

Can you modify this code where
1)The csv files are added in the existing workbook and does not open another workbook
2)Instead of selecting the file name for eg : xxxx.csv it becomes sheet1.csv and so on

Thanks

 

[maabadi]

Try this. But you shouldn't have sheet1 ,2 , (until sheet count) at your workbook
if you want add another Name as S1, S2, S3 Change ActiveSheet.Name = "Sheet" & I to ActiveSheet.Name = "S" & I

Sub CombineCsvFiles()
    Dim xFilesToOpen As Variant, I As Integer, xWb As Workbook, xTempWb As Workbook
    Dim xDelimiter As String, fileName As String, wbNew As Workbook, xScreen As Boolean
    On Error GoTo ErrHandler
    xScreen = Application.ScreenUpdating
    Application.ScreenUpdating = False
    xDelimiter = "|"
    xFilesToOpen = Application.GetOpenFilename("Text Files (*.csv), *.csv", , , , True)
    If TypeName(xFilesToOpen) = "Boolean" Then
        MsgBox "No files were selected"
        GoTo ExitHandler
    End If
    I = 0
    Set xWb = Application.ActiveWorkbook
    Do While I < UBound(xFilesToOpen)
        I = I + 1
        Set xTempWb = Workbooks.Open(xFilesToOpen(I))
        xTempWb.Sheets(1).Move , xWb.Sheets(xWb.Sheets.Count)
        ActiveSheet.Name = "Sheet" & I
    Loop
ExitHandler:
    Application.ScreenUpdating = xScreen
    Set xWb = Nothing
    Set xTempWb = Nothing
    Exit Sub
ErrHandler:
    MsgBox Err.Description
    Resume ExitHandler
End Sub

 

[anuradhagrewal]

Hi
It does what is expected but stops after 3 sheets. Can u tell me what can be added so that the number of sheets that can be added is infinite.

Much obliged

Thanks

Anu

 

[maabadi]

Why stopping after 3 sheets , it should run until count of your selected CSV files. (if you select 5 files go to sheet5 and ...)

 

[anuradhagrewal]

Sorry my bad works fine thanksss a ton