INDEX & MATCH with tables with different sizes

[Torque73]

Hi all,

I am working on a file in order to combine two tables. The results from both tables are combined in the way that the information (A and B) are displayed within the corresponding cell. So far I am using the following formula
=WENNFEHLER(INDEX($B$2:$E$8&" / "&$B$14:$E$18;VERGLEICH($G2;$A$2:$A$8;1);VERGLEICH(H$1;$B$1:$E$1;1));"")
So far it works, but there is a big but. As you can see in the image attached, the tables have different sizes including "x" and "y" different for those of each. That makes, that some
results are not properly "copied" in the final table. Is there any way to come over this problem but without using VBA? I am not allow to used them. The only solution I found so
far is to have the same "x" and "y" for the origin tables and the final one.

Thank you in advance!

 

[Torque73]

Sorry, maybe a better picture of the problem.

 

[Fluff]

Hi & welcome to MrExcel.
How about

+Fluff 1.xlsm
	A	B	C	D	E	F	G	H	I	J	K	L
1		1	2	3	4
2	10	A	A
3	12
4	15	A	A	A
5	20
6	22	A	A	A
7	50		A	A				1	2	3	3.5	4
8	55		A	A			10	A / B	A /	/	/ B	/
9							12	/ B	/	/	/	/
10							15	A / B	A / B	A /	/ B	/
11							20	/	/	/	/	/
12							22	A / B	A / B	A /	/	/
13		1	2	3.5	4		50	/	A /	A /	/	/
14	10	B		B			55	/	A /	A /	/	/
15	12	B
16	15	B	B	B
17	20
18	22	B	B
Master

Cell Formulas
Range	Formula
H8:L14	H8	=TEXTJOIN(" / ",0,IFNA(INDEX($B$2:$E$8,MATCH($G8,$A$2:$A$8,0),MATCH(H$7,$B$1:$E$1,0)),""),IFNA(INDEX($B$14:$E$18,MATCH($G8,$A$14:$A$18,0),MATCH(H$7,$B$13:$E$13,0)),""))

 

[Torque73]

Hi Fluff,

just awesome !! Thank you very much, this has saved me tons of hours building a much larger table than in the example. Just tested in my table and your solution is working properly! Great!
Regards!

 

[Fluff]

You're welcome & thanks for the feedback.