insert name into outlook

[Trevor3007]

Hi,

Dont even know if this is possible/viable?

I currently use the VB below in outlook( basically, it opens a predefined template)

Sub MakeItem()
Set newItem = Application.CreateItemFromTemplate("C:\Users\user\Documents\newphones.oft")
newItem.Display
Set newItem = Nothing
End Sub

once ran, I then insert the 'recipient's first name into & in the body of the message after hi (for example Hi John,).

Is it possible that after i run the above code, enter the recipients email address, that thier first name can be automatically add into the body of the message, after "Hi and before the ","

I hope this makes sense & some VB god can sort for me?

Many thanks in advance.
Kind regards
Trevor

 

[GWteB]

The easiest way to do this is to include a unique placeholder in your template where the name should go, e.g.:

Hi $%name%$,
... bla di bla di bla ...,
Regards,
Trevor3007

Code below might give you a starting point and is running within the VBE of Excel as well. Of course the e-mail address must be suitable for this method, it is therefore just an example.

Sub Trevor3007()

    Const PLACEHOLDER As String = "$%name%$"
    
    Dim olApp       As Object
    Dim newItem     As Object
    Dim EmailAddr   As String
    Dim FirstName   As String

    EmailAddr = "Joe.Bonamassa@domain.com"
    FirstName = Left(EmailAddr, InStr(EmailAddr, ".") - 1)

    Set olApp = VBA.CreateObject("Outlook.Application")
    
    Set newItem = olApp.CreateItemFromTemplate("C:\Users\user\Documents\newphones.oft")
    With newItem
        .Recipients.Add EmailAddr
        If .BodyFormat = 2 Then    ' 2 equ olFormatHTML
            .HTMLBody = VBA.Replace(.HTMLBody, PLACEHOLDER, FirstName)
        Else
            .Body = VBA.Replace(.Body, PLACEHOLDER, FirstName)
        End If
        .Display
    End With

    Set newItem = Nothing
    Set olApp = Nothing
End Sub

 

[Trevor3007]

Hi GWteB,

Thanks for our help.

Got it to work.....FAB.

Have a great rest of your day.