Is it possible to set reminder in outlook calendar when near due date using data from table

[Auri]

I have found similar posts on this but they were not using the table. So I wonder if it's possible to set a reminder in the outlook calendar by taking data from the table like the expiry date and header itself, putting inside the calendar.

A total noob trying to learn this stuff, so I hope to have some help and or given solution to help me. Thanks!

 

[footoo]

Here's a way to do it : How to create Outlook reminders from Excel spreadsheet?

What does your table look like and what info do you want in the calendar?

 

[Auri]

Here's a way to do it : How to create Outlook reminders from Excel spreadsheet?

What does your table look like and what info do you want in the calendar?

List of items and I just want it to have the expiry date and the item name. Can't screenshot since its confidential info though. Would really appreciate any help you can give! Thanks!

 

[footoo]

List of items and I just want it to have the expiry date and the item name. Can't screenshot since its confidential info though. Would really appreciate any help you can give! Thanks!

Need following info :
• What range does your table occupy?
• Does that include a header row?
• What columns contain the expiry dates and item names?
• Do you want to record all table items in the calendar?
• How long before the expiry dates do you want reminders?
• Can you allocate a column for storing an indicator to show a calendar entry has been made? (This is to make it easier for you to update for new entries to the table.)

 

[Auri]

My table occupies from A to J.
It includes a header row.
The column that contains the item name is C and the column with expiry dates is F.
Yes, if possible.
1 week before.
Yes, I can allocate a column for storing an indicator.

Here is the info you will need. I hope what I mentioned is relevant. Thanks!

 

[footoo]

Select in column C the items you want to enter in the Outlook calendar and then :

Sub EnterInCalendar()
Dim xOutApp As Object, cel As Range
If Selection.Columns.Count > 1 Or Selection.Column <> 3 Then
    MsgBox "Select in column C only."
    Exit Sub
End If
Set xOutApp = CreateObject("Outlook.Application")
For Each cel In Selection
    With xOutApp.createitem(1)
        .Subject = cel.Value
        .Start = cel(1, 4).Value
        .End = cel(1, 4).Value + 1
        .AllDayEvent = True
        .ReminderSet = True
        .ReminderMinutesBeforeStart = 10080
        .BusyStatus = 5
        .Save
    End With
    Cells(cel.Row, "K") = "c"
Next
Set xOutApp = Nothing
End Sub

The above assumes column K can be used as an indicator.

 

[Auri]

I will try and let you know.

 

[Auri]

Ok it works, if there's a question for this, I will let you know! Thank you so much for your help!

 

[Auri]

Select in column C the items you want to enter in the Outlook calendar and then :

Sub EnterInCalendar()
Dim xOutApp As Object, cel As Range
If Selection.Columns.Count > 1 Or Selection.Column <> 3 Then
    MsgBox "Select in column C only."
    Exit Sub
End If
Set xOutApp = CreateObject("Outlook.Application")
For Each cel In Selection
    With xOutApp.createitem(1)
        .Subject = cel.Value
        .Start = cel(1, 4).Value
        .End = cel(1, 4).Value + 1
        .AllDayEvent = True
        .ReminderSet = True
        .ReminderMinutesBeforeStart = 10080
        .BusyStatus = 5
        .Save
    End With
    Cells(cel.Row, "K") = "c"
Next
Set xOutApp = Nothing
End Sub

The above assumes column K can be used as an indicator.

Hi, I have a question again. Is it possible to set the time from 9 to 9.30 AM instead of the all-day event? Thanks for the help!

 

[footoo]

Sub EnterInCalendar()
Dim xOutApp As Object, cel As Range
If Selection.Columns.Count > 1 Or Selection.Column <> 3 Then
    MsgBox "Select in column C only."
    Exit Sub
End If
Set xOutApp = CreateObject("Outlook.Application")
For Each cel In Selection
    With xOutApp.createitem(1)
        .Subject = cel.Value
        .Start = cel(1, 4).Value + TimeValue("9:00:00")
        .End = cel(1, 4).Value + TimeValue("9:30:00")
        .ReminderSet = True
        .ReminderMinutesBeforeStart = 10080
        .BusyStatus = 5
        .Save
    End With
    Cells(cel.Row, "K") = "c"
Next
Set xOutApp = Nothing
End Sub