ISBLANK with three conditions

[RuthyTee]

Can anyone help with this excel formula?? I am stumped with this one...

AB1 and AG1 are both blank then return "No PPA"

AB1 has text but AG1 is blank then return "Framework"

AB1 is blank but AG1 has a date then the following formula needs to be used...

IF(AG1-TODAY()>90, "Live", IF(TODAY()-AG1>0, "Expired", "Expiring Soon"

I basically need to merge IF(AND(ISBLANK(AB1),ISBLANK(AG1)),"No PPA",IF(ISBLANK(AG1),"Framework" with IF(AG1-TODAY()>90, "Live", IF(TODAY()-AG1>0, "Expired", "Expiring Soon"

Is this possible?

 

[RAJESH NATH]

EMT931-932.xlsx
	A	B	C
11			NO PPA
12	A		FRAMEWORK
13		1	EXPIRING SOON
Sheet6

Cell Formulas
Range	Formula
C11:C13	C11	=IF((ISBLANK(A11)*ISBLANK(B11)),"NO PPA",IF((ISBLANK(A11)*ISNUMBER(B11)),"EXPIRING SOON",IF((ISTEXT(A11)*ISBLANK(B11)),"FRAMEWORK")))

i am working on date condition that you mention, when i will get, i will update you. for now i am using number instead of date...

 

[Toadstool]

Hi RuthyTee,

I may have gotten a little carried awa with my binary logic but I think this does what you ask:

Book3
	AB					AG	AH
1							No PPA
2	Text						Framework
3						1/1/2020	Expired
4						1/1/2021	Live
5						8/30/2020	Expiring soon
Sheet1

Cell Formulas
Range	Formula
AH1:AH5	AH1	=CHOOSE(BIN2DEC(BITOR(AB1&AG1="",0)&BITAND(ISTEXT(AB1),ISBLANK(AG1))&BITAND(AB1="",ISNUMBER(AG1))),IF(AG1-TODAY()>90,"Live",IF(TODAY()-AG1>0,"Expired","Expiring soon")),"Framework","","No PPA")

 

[Peter_SSs]

Welcome to the MrExcel board!

Is it possible that AB has text and AG has date (row 6 below)? If so, what should the formula return?

Does this do what you want?

20 08 22.xlsm
	AB	AC	AD	AE	AF	AG	AH
1							No PPA
2	Text						Framework
3						1-Jan-2020	Expired
4						1-Jan-2021	Live
5						30-Aug-2020	Expiring soon
6	Text					25-May-2020	?
RuthyTee

Cell Formulas
Range	Formula
AH1:AH6	AH1	=IF(AB1&AG1="","No PPA",IF(AG1="","Framework",IF(AND(AG1,AB1=""),LOOKUP(AG1-TODAY(),{-9999,0.1,90.1},{"Expired","Expiring soon","Live"}),"?")))