IsEmpty(Target) not working in selected range of cells

[nubranger]

My code below does a very simple task. It automatically populates 2 cells within the same row of the target when the target cell is not empty and deletes the same values when the target's value gets deleted (empty).

My issue is with the delete code. It works when I delete individual target cells but not in range (e.g., C3 to C10).

Private Sub Worksheet_Change(ByVal Target As Range)

If Target.Offset.Row > 5 And Target.Offset.Column = 6 Then
    If Not IsEmpty(Target) Then
 
        Target.Offset(0, -4).Value = Target.Offset.Row - 5
        Target.Offset(0, -3).Value = Format(Now, "mm/dd/yyyy")
        Target.Offset(0, -1).Value = Application.UserName
        
    End If
End If

If Target.Offset.Row > 5 And Target.Offset.Column = 6 Then
    If IsEmpty(Target) Then
 
        Target.Offset(0, -4).Value = ""
        Target.Offset(0, -3).Value = ""
        Target.Offset(0, -1).Value = ""
        
    End If
End If

End Sub

 

[jasonb75]

That is not what IsEmpty is meant for,

IsEmpty function (Visual Basic for Applications)

Office VBA reference topic

docs.microsoft.com

You need to loop through the cells and check if each cell is <>"" or =""

Private Sub Worksheet_Change(ByVal Target As Range)
Dim c As Range
For Each c In Target
    If c.Row > 5 And c.Column = 6 Then
        If c.Value <> "" Then
            c.Offset(0, -4).Value = c.Offset.Row - 5
            c.Offset(0, -3).Value = Format(Now, "mm/dd/yyyy")
            c.Offset(0, -1).Value = Application.UserName
        Else
            c.Offset(0, -4).ClearContents
            c.Offset(0, -3).ClearContents
            c.Offset(0, -1).ClearContents
        End If
    End If
Next
End Sub