List all conditional formatting rules in a workbook

R

ReignEternal

New Member
Joined
Apr 11, 2021
Messages
41
Office Version
  1. 365
Platform
  1. Windows
Hello,
I have a situation where I am trying to list all conditional formatting rules that are in an entire workbook. In this forum I was able to find a thread that is over 3400 days old. Thread is titled "List all conditional formatting rules in a worksheet". In that thread, this is the VBA

VBA Code: 
Function FCTypeFromIndex(lIndex As Long) As String
   
    Select Case lIndex
        Case 12: FCTypeFromIndex = "Above Average"
        Case 10: FCTypeFromIndex = "Blanks"
        Case 1: FCTypeFromIndex = "Cell Value"
        Case 3: FCTypeFromIndex = "Color Scale"
        Case 4: FCTypeFromIndex = "DataBar"
        Case 16: FCTypeFromIndex = "Errors"
        Case 2: FCTypeFromIndex = "Expression"
        Case 6: FCTypeFromIndex = "Icon Sets"
        Case 14: FCTypeFromIndex = "No Blanks"
        Case 17: FCTypeFromIndex = "No Errors"
        Case 9: FCTypeFromIndex = "Text"
        Case 11: FCTypeFromIndex = "Time Period"
        Case 5: FCTypeFromIndex = "Top 10?"
        Case 8: FCTypeFromIndex = "Unique Values"
        Case Else: FCTypeFromIndex = "Unknown"
    End Select
       
End Function
Sub ShowConditionalFormatting()
   
    Dim cf As Variant
    Dim rCell As Range
    Dim colFormats As Collection
    Dim i As Long
    Dim wsOutput As Worksheet
   
    Set colFormats = New Collection
   
    For Each rCell In Worksheets("Fin Stmt").Cells.SpecialCells(xlCellTypeAllFormatConditions).Cells
        For i = 1 To rCell.FormatConditions.Count
            On Error Resume Next
                colFormats.Add rCell.FormatConditions.Item(i), rCell.FormatConditions(i).AppliesTo.Address
            On Error GoTo 0
        Next i
    Next rCell
       
    Set wsOutput = Workbooks.Add.Worksheets(1)
    wsOutput.Range("A1:E1").Value = Array("Type", "Applies To", "StopIfTrue", "Formual1", "Worksheet")
   
    For i = 1 To colFormats.Count
        Set cf = colFormats(i)
       
        With wsOutput.Cells(i + 1, 1)
            .Value = FCTypeFromIndex(cf.Type)
            .Offset(0, 1).Value = cf.AppliesTo.Address
            .Offset(0, 2).Value = cf.StopIfTrue
            .Offset(0, 4).Value = cf.ThisWorksheet
            On Error Resume Next
                .Offset(0, 3).Value = "'" & cf.Formula1
            On Error GoTo 0
        End With
    Next i
   
    wsOutput.UsedRange.EntireColumn.AutoFit
   
End Sub

I have tested it and it only does a single worksheet and it only works on that one worksheet. Im looking to find all conditional formatting in the entire workbook and in the results, tell me which worksheet the CF lives on
 

Excel Facts

What does custom number format of ;;; mean?
Three semi-colons will hide the value in the cell. Although most people use white font instead.
Sort by date Sort by votes
Here is a revision that will analyze all sheets in the active workbook.
VBA Code: 
Option Explicit

Private Function FCTypeFromIndex(lIndex As Long) As String
   
    Select Case lIndex
        Case 12: FCTypeFromIndex = "Above Average"
        Case 10: FCTypeFromIndex = "Blanks"
        Case 1: FCTypeFromIndex = "Cell Value"
        Case 3: FCTypeFromIndex = "Color Scale"
        Case 4: FCTypeFromIndex = "DataBar"
        Case 16: FCTypeFromIndex = "Errors"
        Case 2: FCTypeFromIndex = "Expression"
        Case 6: FCTypeFromIndex = "Icon Sets"
        Case 14: FCTypeFromIndex = "No Blanks"
        Case 17: FCTypeFromIndex = "No Errors"
        Case 9: FCTypeFromIndex = "Text"
        Case 11: FCTypeFromIndex = "Time Period"
        Case 5: FCTypeFromIndex = "Top 10?"
        Case 8: FCTypeFromIndex = "Unique Values"
        Case Else: FCTypeFromIndex = "Unknown"
    End Select
       
End Function

Public Sub ShowConditionalFormatting()
   
    Dim cf As Variant
    Dim rCell As Range
    Dim colFormats As Collection
    Dim i As Long
    Dim OutputRow As Long
    Dim wsOutput As Worksheet
    Dim WS As Worksheet
    Dim ColCount As Long
    Dim CFCells As Range
    Dim WorkbookToCheck As Workbook
    
    
    Set WorkbookToCheck = ActiveWorkbook
    
    Set wsOutput = Workbooks.Add.Worksheets(1)
    wsOutput.Range("A1:E1").Value = Array("Type", "Applies To", "StopIfTrue", "Formual1", "Worksheet")
    
    OutputRow = 1
    For Each WS In WorkbookToCheck.Worksheets
    
       Set colFormats = New Collection
    
       On Error Resume Next ' if there are no CF cells an error will be raised and CFCells will be Nothing
       Set CFCells = WS.Cells.SpecialCells(xlCellTypeAllFormatConditions).Cells
       On Error GoTo 0
       
       If Not CFCells Is Nothing Then
         For Each rCell In CFCells
             For i = 1 To rCell.FormatConditions.Count
                 On Error Resume Next
                     colFormats.Add rCell.FormatConditions.Item(i), rCell.FormatConditions(i).AppliesTo.Address
                 On Error GoTo 0
             Next i
         Next rCell
       End If
          
      
       For i = 1 To colFormats.Count
           Set cf = colFormats(i)
          
           OutputRow = OutputRow + 1
           With wsOutput.Cells(OutputRow, 1)
               .Value = FCTypeFromIndex(cf.Type)
               .Offset(0, 1).Value = cf.AppliesTo.Address
               .Offset(0, 2).Value = cf.StopIfTrue
               .Offset(0, 4).Value = WS.Name ' error on ThisWorksheet in original code
               On Error Resume Next
                   .Offset(0, 3).Value = "'" & cf.Formula1
               On Error GoTo 0
           End With
       Next i
       
    Next WS
   
    wsOutput.UsedRange.EntireColumn.AutoFit
   
End Sub
 
Upvote 0
Solution
6StringJazzer said:
Here is a revision that will analyze all sheets in the active workbook.
VBA Code: 
Option Explicit

Private Function FCTypeFromIndex(lIndex As Long) As String
  
    Select Case lIndex
        Case 12: FCTypeFromIndex = "Above Average"
        Case 10: FCTypeFromIndex = "Blanks"
        Case 1: FCTypeFromIndex = "Cell Value"
        Case 3: FCTypeFromIndex = "Color Scale"
        Case 4: FCTypeFromIndex = "DataBar"
        Case 16: FCTypeFromIndex = "Errors"
        Case 2: FCTypeFromIndex = "Expression"
        Case 6: FCTypeFromIndex = "Icon Sets"
        Case 14: FCTypeFromIndex = "No Blanks"
        Case 17: FCTypeFromIndex = "No Errors"
        Case 9: FCTypeFromIndex = "Text"
        Case 11: FCTypeFromIndex = "Time Period"
        Case 5: FCTypeFromIndex = "Top 10?"
        Case 8: FCTypeFromIndex = "Unique Values"
        Case Else: FCTypeFromIndex = "Unknown"
    End Select
      
End Function

Public Sub ShowConditionalFormatting()
  
    Dim cf As Variant
    Dim rCell As Range
    Dim colFormats As Collection
    Dim i As Long
    Dim OutputRow As Long
    Dim wsOutput As Worksheet
    Dim WS As Worksheet
    Dim ColCount As Long
    Dim CFCells As Range
    Dim WorkbookToCheck As Workbook
   
   
    Set WorkbookToCheck = ActiveWorkbook
   
    Set wsOutput = Workbooks.Add.Worksheets(1)
    wsOutput.Range("A1:E1").Value = Array("Type", "Applies To", "StopIfTrue", "Formual1", "Worksheet")
   
    OutputRow = 1
    For Each WS In WorkbookToCheck.Worksheets
   
       Set colFormats = New Collection
   
       On Error Resume Next ' if there are no CF cells an error will be raised and CFCells will be Nothing
       Set CFCells = WS.Cells.SpecialCells(xlCellTypeAllFormatConditions).Cells
       On Error GoTo 0
      
       If Not CFCells Is Nothing Then
         For Each rCell In CFCells
             For i = 1 To rCell.FormatConditions.Count
                 On Error Resume Next
                     colFormats.Add rCell.FormatConditions.Item(i), rCell.FormatConditions(i).AppliesTo.Address
                 On Error GoTo 0
             Next i
         Next rCell
       End If
         
     
       For i = 1 To colFormats.Count
           Set cf = colFormats(i)
         
           OutputRow = OutputRow + 1
           With wsOutput.Cells(OutputRow, 1)
               .Value = FCTypeFromIndex(cf.Type)
               .Offset(0, 1).Value = cf.AppliesTo.Address
               .Offset(0, 2).Value = cf.StopIfTrue
               .Offset(0, 4).Value = WS.Name ' error on ThisWorksheet in original code
               On Error Resume Next
                   .Offset(0, 3).Value = "'" & cf.Formula1
               On Error GoTo 0
           End With
       Next i
      
    Next WS
  
    wsOutput.UsedRange.EntireColumn.AutoFit
  
End Sub
Click to expand...
Thank you for this and thanks for the notes inside the VBA. I am testing it now. i will let you know my results.
 
Upvote 0
6StringJazzer said:
Here is a revision that will analyze all sheets in the active workbook.
VBA Code: 
Option Explicit

Private Function FCTypeFromIndex(lIndex As Long) As String
  
    Select Case lIndex
        Case 12: FCTypeFromIndex = "Above Average"
        Case 10: FCTypeFromIndex = "Blanks"
        Case 1: FCTypeFromIndex = "Cell Value"
        Case 3: FCTypeFromIndex = "Color Scale"
        Case 4: FCTypeFromIndex = "DataBar"
        Case 16: FCTypeFromIndex = "Errors"
        Case 2: FCTypeFromIndex = "Expression"
        Case 6: FCTypeFromIndex = "Icon Sets"
        Case 14: FCTypeFromIndex = "No Blanks"
        Case 17: FCTypeFromIndex = "No Errors"
        Case 9: FCTypeFromIndex = "Text"
        Case 11: FCTypeFromIndex = "Time Period"
        Case 5: FCTypeFromIndex = "Top 10?"
        Case 8: FCTypeFromIndex = "Unique Values"
        Case Else: FCTypeFromIndex = "Unknown"
    End Select
      
End Function

Public Sub ShowConditionalFormatting()
  
    Dim cf As Variant
    Dim rCell As Range
    Dim colFormats As Collection
    Dim i As Long
    Dim OutputRow As Long
    Dim wsOutput As Worksheet
    Dim WS As Worksheet
    Dim ColCount As Long
    Dim CFCells As Range
    Dim WorkbookToCheck As Workbook
   
   
    Set WorkbookToCheck = ActiveWorkbook
   
    Set wsOutput = Workbooks.Add.Worksheets(1)
    wsOutput.Range("A1:E1").Value = Array("Type", "Applies To", "StopIfTrue", "Formual1", "Worksheet")
   
    OutputRow = 1
    For Each WS In WorkbookToCheck.Worksheets
   
       Set colFormats = New Collection
   
       On Error Resume Next ' if there are no CF cells an error will be raised and CFCells will be Nothing
       Set CFCells = WS.Cells.SpecialCells(xlCellTypeAllFormatConditions).Cells
       On Error GoTo 0
      
       If Not CFCells Is Nothing Then
         For Each rCell In CFCells
             For i = 1 To rCell.FormatConditions.Count
                 On Error Resume Next
                     colFormats.Add rCell.FormatConditions.Item(i), rCell.FormatConditions(i).AppliesTo.Address
                 On Error GoTo 0
             Next i
         Next rCell
       End If
         
     
       For i = 1 To colFormats.Count
           Set cf = colFormats(i)
         
           OutputRow = OutputRow + 1
           With wsOutput.Cells(OutputRow, 1)
               .Value = FCTypeFromIndex(cf.Type)
               .Offset(0, 1).Value = cf.AppliesTo.Address
               .Offset(0, 2).Value = cf.StopIfTrue
               .Offset(0, 4).Value = WS.Name ' error on ThisWorksheet in original code
               On Error Resume Next
                   .Offset(0, 3).Value = "'" & cf.Formula1
               On Error GoTo 0
           End With
       Next i
      
    Next WS
  
    wsOutput.UsedRange.EntireColumn.AutoFit
  
End Sub
Click to expand...
6StringJazzer, Your VBA did work. It helped me realize that I was actually looking for something much more complex. so I found this from a forum that shut down the thread. The following VBA took roughly 2 hours to fully run but gave the complexities I didn't know I was looking for.


VBA Code: 
Option Explicit
Option Private Module

Private mlngPos As Long

Private Function CFAboveAverage(xloperator As Long) As String
   Select Case xloperator
      Case 0:                 CFAboveAverage = "Above Avg"
      Case 1:                 CFAboveAverage = "Below Avg"
      Case 2:                 CFAboveAverage = "Equal or Above Avg"
      Case 3:                 CFAboveAverage = "Equal or Below Avg"
      Case 4:                 CFAboveAverage = "Above Std Dev"
      Case 5:                 CFAboveAverage = "Below Std Dev"
      Case Else:              CFAboveAverage = "Unknown"
   End Select
End Function

Private Function CFDateOperator(xloperator As Long) As String
   Select Case xloperator
      Case 0:                 CFDateOperator = "Today"
      Case 1:                 CFDateOperator = "Yesterday"
      Case 2:                 CFDateOperator = "Last 7 days"
      Case 3:                 CFDateOperator = "This Week"
      Case 4:                 CFDateOperator = "Last Week"
      Case 5:                 CFDateOperator = "Last Month"
      Case 6:                 CFDateOperator = "Tomorrow"
      Case 7:                 CFDateOperator = "Next Week"
      Case 8:                 CFDateOperator = "Next Month"
      Case 9:                 CFDateOperator = "This Month"
      Case Else:              CFDateOperator = "Unknown"
   End Select
End Function

Private Function CFOperator(xloperator As Long) As String
   Select Case xloperator
      Case xlBetween:         CFOperator = "Between"
      Case xlNotBetween:      CFOperator = "Not Between"
      Case xlEqual:           CFOperator = "Equal"
      Case xlNotEqual:        CFOperator = "Not Equal"
      Case xlGreater:         CFOperator = "Greater"
      Case xlLess:            CFOperator = "Less"
      Case xlGreaterEqual:    CFOperator = "Greater or Equal"
      Case xlLessEqual:       CFOperator = "Less or Equal"
   End Select
End Function

Private Function CFTextOperator(xloperator As Long) As String
   Select Case xloperator
      Case 0:                 CFTextOperator = "Contains"
      Case 1:                 CFTextOperator = "Does not contain"
      Case 2:                 CFTextOperator = "Begins with"
      Case 3:                 CFTextOperator = "Ends with"
   End Select
End Function

Sub DeleteCFSheet()
   On Error Resume Next
   ActiveSheet.Cells.SpecialCells(xlCellTypeAllFormatConditions).FormatConditions.Delete
   On Error GoTo 0
End Sub

Sub DeleteCFWorkbook()
   Dim objWsh  As Worksheet
   
   On Error Resume Next
   For Each objWsh In ActiveWorkbook.Worksheets
      objWsh.Cells.SpecialCells(xlCellTypeAllFormatConditions).FormatConditions.Delete
   Next objWsh
   On Error GoTo 0
End Sub

Private Function FCTypeFromIndex(lIndex As Long) As String
   
   Select Case lIndex
      Case 12:    FCTypeFromIndex = "Above Average"
      Case 10:    FCTypeFromIndex = "Blanks"
      Case 1:     FCTypeFromIndex = "Cell Value"
      Case 3:     FCTypeFromIndex = "Color Scale"
      Case 4:     FCTypeFromIndex = "DataBar"
      Case 16:    FCTypeFromIndex = "Errors"
      Case 2:     FCTypeFromIndex = "Expression"
      Case 6:     FCTypeFromIndex = "Icon Sets"
      Case 13:    FCTypeFromIndex = "No Blanks"
      Case 17:    FCTypeFromIndex = "No Errors"
      Case 9:     FCTypeFromIndex = "Text"
      Case 11:    FCTypeFromIndex = "Time Period"
      Case 5:     FCTypeFromIndex = "Top 10?"
      Case 8:     FCTypeFromIndex = "Unique Values"
      Case Else:  FCTypeFromIndex = "Unknown"
   End Select
       
End Function

Sub ShowConditionalFormatting()
   Dim rngCell          As Range
   Dim lngI             As Long
   Dim objOutput        As Worksheet
   Dim objWsh           As Worksheet
   Dim objSource        As Workbook
   Dim intArea          As Integer
   
   Application.ScreenUpdating = False
   
   Set objSource = ActiveWorkbook
   
   ''' Prepare the output
   Set objOutput = Workbooks.Add.Worksheets(1)
   With objOutput.Cells(1, 1)
      .Value = "Workbook:"
      .Font.Size = 14
      .Font.Color = 16777215
      .Interior.Color = 3506772
   End With
   
   With objOutput.Cells(2, 1)
      .Value = "Date:"
      .Font.Size = 14
      .Font.Color = 16777215
      .Interior.Color = 3506772
   End With
   
   With objOutput
      .Cells(1, 2) = ActiveWorkbook.Name
      .Cells(2, 2) = Date
   End With
   
   mlngPos = 4
   
   objSource.Activate
   For Each objWsh In objSource.Worksheets
      Application.StatusBar = "Analysing sheet: " & objWsh.Name
      If mlngPos > 4 Then mlngPos = objOutput.Cells(Rows.Count, 2).End(xlUp).Row + 2
      With objOutput
         .Range(.Cells(mlngPos, 2), .Cells(mlngPos, 8)) = Array("Type", "Range", "StopIfTrue", "Operator", "Formual1", "Formual2", "Color")
         .Cells(mlngPos, 1) = objWsh.Name
         .Range(.Cells(mlngPos, 1), .Cells(mlngPos, 8)).Font.Size = 14
         .Range(.Cells(mlngPos, 1), .Cells(mlngPos, 8)).Font.Color = 16777215
         .Range(.Cells(mlngPos, 1), .Cells(mlngPos, 8)).Interior.Color = 3506772
      End With
      objWsh.Activate
      On Error Resume Next
      lngI = 0
      lngI = objWsh.Cells.SpecialCells(xlCellTypeAllFormatConditions).Cells.CountLarge
      On Error GoTo 0
      If lngI > 0 Then
         For intArea = 1 To objWsh.Cells.SpecialCells(xlCellTypeAllFormatConditions).Areas.Count
            Set rngCell = objWsh.Cells.SpecialCells(xlCellTypeAllFormatConditions).Areas(intArea)
            WriteOutput objOutput, rngCell
         Next intArea
      Else
         Set rngCell = Nothing
         WriteOutput objOutput, rngCell
      End If
   Next objWsh
   
   objOutput.UsedRange.EntireColumn.AutoFit
   objOutput.Activate
   Set objOutput = Nothing
   Set objWsh = Nothing
   Set objSource = Nothing
   Application.StatusBar = False
   Application.ScreenUpdating = True
End Sub

Sub WriteOutput(objOutput As Worksheet, rngCell As Range)
   Dim lngI       As Long
   
   mlngPos = objOutput.Cells(Rows.Count, 2).End(xlUp).Row
   If objOutput.Cells(mlngPos, 2) = "Type" Then mlngPos = mlngPos + 1
   If Not rngCell Is Nothing Then
      For lngI = 1 To rngCell.FormatConditions.Count
         With objOutput.Cells(mlngPos + lngI, 2)
            .Value = FCTypeFromIndex(rngCell.FormatConditions(lngI).Type)
            .Offset(0, 1).Value = rngCell.FormatConditions(lngI).AppliesTo.Address
            .Offset(0, 2).Value = rngCell.FormatConditions(lngI).StopIfTrue
            On Error Resume Next
            Select Case rngCell.FormatConditions(lngI).Type
               Case 1:
                  .Offset(0, 3).Value = CFOperator(rngCell.FormatConditions(lngI).Operator)
                  .Offset(0, 4).Value = rngCell.FormatConditions(lngI).Formula1
                  .Offset(0, 5).Value = rngCell.FormatConditions(lngI).Formula2
                  .Offset(0, 6).Interior.Color = rngCell.FormatConditions(lngI).Interior.Color
               Case 2:
                  .Offset(0, 4).Value = "'" & rngCell.FormatConditions(lngI).Formula1
                  .Offset(0, 5).Value = "'" & rngCell.FormatConditions(lngI).Formula2
                  .Offset(0, 6).Interior.Color = rngCell.FormatConditions(lngI).Interior.Color
               Case 3:
                  .Offset(0, 4).Value = "'" & rngCell.FormatConditions(lngI).ColorScaleCriteria(1).Value
                  .Offset(0, 5).Value = "'" & rngCell.FormatConditions(lngI).ColorScaleCriteria(2).Value
                  .Offset(0, 6).Interior.Color = rngCell.FormatConditions(lngI).ColorScaleCriteria(1).FormatColor.Color
               Case 4:
                  .Offset(0, 6).Interior.Color = rngCell.FormatConditions(lngI).BarColor.Color
               Case 5:
                  .Offset(0, 4).Value = rngCell.FormatConditions(lngI).Rank
                  .Offset(0, 6).Interior.Color = rngCell.FormatConditions(lngI).Interior.Color
               Case 6:
                  '.Offset(0, 3).Value = rngCell.FormatConditions(lngI).IconCriteria(1).Operator
                  '.Offset(0, 4).Value = rngCell.FormatConditions(lngI).IconCriteria(1).Value
                  '.Offset(0, 5).Value = rngCell.FormatConditions(lngI).IconCriteria(2).Value
               Case 7:
               Case 8:
                  .Offset(0, 3).Value = IIf(rngCell.FormatConditions(lngI).DupeUnique = 0, "Unique", "Duplicates")
                  .Offset(0, 6).Interior.Color = rngCell.FormatConditions(lngI).Interior.Color
               Case 9:
                  .Offset(0, 3).Value = CFTextOperator(rngCell.FormatConditions(lngI).TextOperator)
                  .Offset(0, 4).Value = Left(Mid(rngCell.FormatConditions(lngI).Formula1, InStr(rngCell.FormatConditions(lngI).Formula1, Chr(34)) + 1), InStr(Mid(rngCell.FormatConditions(lngI).Formula1, InStr(rngCell.FormatConditions(lngI).Formula1, Chr(34)) + 1), Chr(34)) - 1)
                  .Offset(0, 6).Interior.Color = rngCell.FormatConditions(lngI).Interior.Color
               Case 10:
                  .Offset(0, 6).Interior.Color = rngCell.FormatConditions(lngI).Interior.Color
               Case 11:
                  .Offset(0, 3).Value = CFDateOperator(rngCell.FormatConditions(lngI).DateOperator)
                  .Offset(0, 6).Interior.Color = rngCell.FormatConditions(lngI).Interior.Color
               Case 12:
                  .Offset(0, 3).Value = CFAboveAverage(rngCell.FormatConditions(lngI).AboveBelow)
                  .Offset(0, 6).Interior.Color = rngCell.FormatConditions(lngI).Interior.Color
               Case 13:
                  .Offset(0, 6).Interior.Color = rngCell.FormatConditions(lngI).Interior.Color
               Case 14:
               Case 15:
               Case 16:
                  .Offset(0, 6).Interior.Color = rngCell.FormatConditions(lngI).Interior.Color
               Case 17:
                  .Offset(0, 6).Interior.Color = rngCell.FormatConditions(lngI).Interior.Color
               Case Else
            End Select
            On Error GoTo 0
         End With
      Next lngI
      
   Else
      objOutput.Cells(mlngPos + 1, 1) = "No conditional formats in sheet"
   End If
End Sub
 
Upvote 0
The provided answer in post #2 solves the original problem about processing all worksheet in the workbook. Therefore, the marked solution has been changed accordingly.
 
Upvote 0
You must log in or register to reply here.

Similar threads

P
  • Solved
Extra condition in search VBA.
Replies
2
Views
164
pete4monc
P
F
  • Solved
Macro to add sum to all worksheets in a workbook except for a certain worksheets
Replies
3
Views
261
Alex Blakenburg
A
E
  • Question
Change Log With VBA
2
Replies
19
Views
374
Joe4
Joe4
S
  • Question
Count coloured cells in a range which has been conditionally formatted
Replies
1
Views
327
awoohaw
awoohaw
B
  • Question
Matching Multiple Header Row Cell Values - Copy the data below to next available row.
Replies
1
Views
207
bobaol
B

Forum statistics

Threads
1,214,918
Messages
6,122,241
Members
449,075
Latest member
staticfluids

Share this page

We've detected that you are using an adblocker.

We have a great community of people providing Excel help here, but the hosting costs are enormous. You can help keep this site running by allowing ads on MrExcel.com.
Allow Ads at MrExcel

Which adblocker are you using?

Disable AdBlock

Follow these easy steps to disable AdBlock

1)Click on the icon in the browser’s toolbar.
2)Click on the icon in the browser’s toolbar.
2)Click on the "Pause on this site" option.
Go back

Disable AdBlock Plus

Follow these easy steps to disable AdBlock Plus

1)Click on the icon in the browser’s toolbar.
2)Click on the toggle to disable it for "mrexcel.com".
Go back

Disable uBlock Origin

Follow these easy steps to disable uBlock Origin

1)Click on the icon in the browser’s toolbar.
2)Click on the "Power" button.
3)Click on the "Refresh" button.
Go back

Disable uBlock

Follow these easy steps to disable uBlock

1)Click on the icon in the browser’s toolbar.
2)Click on the "Power" button.
3)Click on the "Refresh" button.
Go back
Back
Top