Load image in a form

[erutherford]

Trying to load an image into a form. I thought ListIndex would do the trick. Images are stored in the data table (MyCars) col. "O". The code creates an error "Object error"

Private Sub cbxdrpdwn_Change()
    Dim lastrow As Long, ws As Worksheet
    Dim ans As String
    ans = Me.cbxdrpdwn.Value
    Set ws = Sheets("MyCars")
    lastrow = ws.Range("D" & Rows.Count).End(xlUp).Row

    '***** Start Code

    For i = 2 To lastrow
        If ws.Cells(i, "D").Value = ans Then
            MsgBox "Confirm" & Me.cbxdrpdwn.Value
            'Change back to white after selection
            Me.cbxdrpdwn.BackColor = vbWhite

            Me.tbxYear = ws.Cells(i, "A").Value
            Me.tbxMake = ws.Cells(i, "B").Value
            Me.tbxModel = ws.Cells(i, "C").Value
            Me.tbxLicense = ws.Cells(i, "E").Value
            Me.tbxColor = ws.Cells(i, "F").Value
            Me.tbxVIN = ws.Cells(i, "G").Value
            Me.tbxpdate = ws.Cells(i, "H").Value
            Me.tbxPAmt = ws.Cells(i, "I").Value
            Me.tbxPAmt = Format(tbxPAmt, "$#,##0.00")
            Me.tbxPMiles = ws.Cells(i, "J").Value
            Me.obYes = ws.Cells(i, "L").Value
            Me.obNo = ws.Cells(i, "M").Value
            Me.Image2.Picture = LoadPicture(MyCars.List(MyCars.ListIndex, 14))
            Me.TextBox2 = ws.Cells(i, "O").Value

            Exit Sub
        End If
    Next i
End Sub

any ideas?
thanks to all

 

[Logit]

Column "O" is 15 , not 14.

 

[erutherford]

Thanks Logit, but still getting the object error. Any ideas?

 

[Logit]

Can you post your workbook for download ? No confidential information to be included.

 

[dmt32]

Hi,
This is just a guess but see if this update to your code resolves the issue

Private Sub cbxdrpdwn_Change()
    Dim lastrow     As Long
    Dim ws          As Worksheet
    Dim ans         As String, ImageFullFilePath As String
   
    ans = Me.cbxdrpdwn.Value
    If Len(ans) = 0 Then Exit Sub
   
    Set ws = Sheets("MyCars")
    lastrow = ws.Range("D" & Rows.Count).End(xlUp).Row
   
    'get full filepath (assumes table has header row)
    ImageFullFilePath = ws.Cells(Me.cbxdrpdwn.ListIndex + 2, 15).Text
   
    '***** Start Code
   
    For i = 2 To lastrow
        If ws.Cells(i, "D").Value = ans Then
            MsgBox "Confirm" & Me.cbxdrpdwn.Value
            'Change back to white after selection
            Me.cbxdrpdwn.BackColor = vbWhite
           
            Me.tbxYear = ws.Cells(i, "A").Value
            Me.tbxMake = ws.Cells(i, "B").Value
            Me.tbxModel = ws.Cells(i, "C").Value
            Me.tbxLicense = ws.Cells(i, "E").Value
            Me.tbxColor = ws.Cells(i, "F").Value
            Me.tbxVIN = ws.Cells(i, "G").Value
            Me.tbxpdate = ws.Cells(i, "H").Value
            Me.tbxPAmt = ws.Cells(i, "I").Value
            Me.tbxPAmt = Format(tbxPAmt, "$#,##0.00")
            Me.tbxPMiles = ws.Cells(i, "J").Value
            Me.obYes = ws.Cells(i, "L").Value
            Me.obNo = ws.Cells(i, "M").Value
           
            If Dir(ImageFullFilePath) <> "" Then
                'image file exists load picture
                Me.Image2.Picture = LoadPicture(ImageFullFilePath)
            Else
                'clear
                Me.Image2.Picture = Nothing
            End If
           
            Me.TextBox2 = ws.Cells(i, "O").Value
           
            Exit Sub
        End If
    Next i
   
End Sub

If still not working, as already requested, place copy of your workbook on a file sharing site like dropbox

Dave

 

[erutherford]

Works perfect! I also see where my problems were in creating this. Many thanks Dave!

 

[dmt32]

Works perfect! I also see where my problems were in creating this. Many thanks Dave!

Glad guess correct & all resolved
Many thanks for feedback

Dave