Loop through Array of Sheets, run code

[willastrowalker]

I've got this code, right, and I'm trying to have it run on speicific sheets only (that don't change). The code is just running 6 times on the same sheet.

The code is supposed to delete current outline, outline the page based on values in Column A/Row 1, and then show the outline to level 3 (out of 4).

Sub Allsheets()

    Dim ws As Variant
    Dim Matrixes As Variant

   Matrixes = Array("Net (Receivables - Payables)", "Gross Due From (Payables)", "Gross Due To (Receivables)", "Receivables Net", "Payables Net", "Gross Due From (Receivables)", "Gross Due To (Payables)")
   
              
    For Each ws In Matrixes
        
        Cells.ClearOutline
        OutlinePage
        ActiveSheet.Outline.ShowLevels ColumnLevels:=3
        ActiveSheet.Outline.ShowLevels RowLevels:=3
    
    Next ws

    
    Application.ScreenUpdating = True
    Application.Calculation = xlCalculationManual

End Sub

 

[HaHoBe]

Hi,

no other sheet is chosen in the code:

Sub Allsheets_re()

  Dim ws As Worksheet
  Dim Matrixes As Variant
 
  Matrixes = Array("Net (Receivables - Payables)", "Gross Due From (Payables)", "Gross Due To (Receivables)", "Receivables Net", "Payables Net", "Gross Due From (Receivables)", "Gross Due To (Payables)")
   
  'runs in active workbook
  For Each ws In Worksheets(Matrixes)
    
    ws.Cells.ClearOutline
    'next codeline is not available in Excel20919?
    ws.OutlinePage
    ws.Outline.ShowLevels ColumnLevels:=3
    ws.Outline.ShowLevels RowLevels:=3

  Next ws

  Application.ScreenUpdating = True
  Application.Calculation = xlCalculationManual '???
End Sub

Ciao,
Holger

 

[Sequoyah]

Hi all,
an alternative solution

Dim ws As Worksheet
                
    For Each ws In Sheets(Array("Net (Receivables - Payables)", "Gross Due From (Payables)", "Gross Due To (Receivables)", "Receivables Net", "Payables Net", "Gross Due From (Receivables)", "Gross Due To (Payables)"))
    
       'my code here
            
    Next ws

' also   Application.ScreenUpdating = True is never been set to False