Loop thru Subdirectories find all .xls update value of specific cells

nhnana

New Member
Joined
Dec 28, 2010
Messages
3
Hello, I need code to loop thru all subdirectories open each workbook in the subdirectory that contains as part of the file name "_Sales Order.xls" and open each "_Sales Order.xls" and update worksheet "Sales Order Form" the following values:
C44 new value = "00-440"
D44 new value = " a few words"
H44 new value = "00-440"

Any help is very much appreciated! Directory structure looks like
N:\\Customers\ABC\January_Sales Order.xls
Thank you so much.
 

Domenic

MrExcel MVP
Joined
Mar 10, 2004
Messages
19,013
Try...

Code:
Option Explicit

Sub test()

    Dim objFSO As Object
    Dim objFolder As Object
    Dim objSubFolder As Object
    Dim objFile As Object
    Dim MyPath As String
    Dim wkbOpen As Workbook
    Dim Cnt As Long
    
    Application.ScreenUpdating = False
    
    MyPath = "N:\\Customers"
    
    Set objFSO = CreateObject("Scripting.FileSystemObject")
    
    Set objFolder = objFSO.GetFolder(MyPath)
    
    For Each objSubFolder In objFolder.SubFolders
        For Each objFile In objSubFolder.Files
            If LCase(objFile.Name) Like "*_sales order.xls" Then
                Set wkbOpen = Workbooks.Open(objFile)
                With wkbOpen.Worksheets("Sales Order Form")
                    .Range("C44").Value = "00-440"
                    .Range("D44").Value = "a few words"
                    .Range("H44").Value = "00-440"
                End With
                wkbOpen.Close savechanges:=True
                Cnt = Cnt + 1
            End If
        Next objFile
    Next objSubFolder
    
    Application.ScreenUpdating = True
    
    If Cnt = 0 Then
        MsgBox "No '_sales order.xls' files found...", vbInformation
    Else
        MsgBox "Completed...", vbInformation
    End If
    
End Sub
 

nhnana

New Member
Joined
Dec 28, 2010
Messages
3
Domenic, Thank you so very much, I will try it right now - I also appreciate the quick response !
 

nhnana

New Member
Joined
Dec 28, 2010
Messages
3
The code worked perfectly ! Processed 312 files in no time at all ! Thank you so very much !
 

Forum statistics

Threads
1,082,273
Messages
5,364,159
Members
400,784
Latest member
reddsables

Some videos you may like

This Week's Hot Topics

  • populate from drop list with multiple tables
    Hi All, i have a drop list that displays data, what i want is when i select one of those from the list to populate text from different tables on...
  • Find list of words from sheet2 in sheet1 before a comma and extract text vba
    Hi Friends, Trying to find the solution on my task. But did not find suitable one to the need. Here is my query and sample file with details...
  • Dynamic Formula entry - VBA code sought
    Hello, really hope one of you experts can help with this - i've spent hours on this and getting no-where. .I have a set of data (more rows than...
  • Listbox Header
    Have a named range called "AccidentsHeader" Within my code I have: [CODE]Private Sub CommandButton1_Click() ListBox1.RowSource =...
  • Complex Heat Map using conditional formatting
    Good day excel world. I have a concern. Below link have a list of countries that carries each country unique data. [URL...
  • Conditional formatting
    Hi good morning, hope you can help me please, I have cells P4:P54 and if this cell is equal to 1 then i want row O to say "Fully Utilised" and to...
Top