Macro Coding Help

[andyreloaded]

I have a spreadsheet with 50 or so tabs that I want to protect and unprotect with a macro. So when I run the LOCK macro, it prompts once for a password, then cycles through all the sheets locking them with that password. And when I run the UNLOCK macro, it prompts once for my password, then cycles through all the sheets unlocking them with that password.

Here is what I have so far, but it has the password actually coded into the macro instead of prompting. Thanks for all your help, as always!

LOCK

Sub LockFormulas()
Dim WkSht As Integer
For WkSht = 1 To Worksheets.Count
With Sheets(WkSht)
On Error Resume Next
.Cells.Locked = False
.Cells.SpecialCells(xlCellTypeFormulas, 23).Locked = True
.Protect "mypassword"
Err.Clear
End With
Next WkSht
End Sub

UNLOCK

Sub UnlockFormulas()
Dim WkSht As Integer
For WkSht = 1 To Worksheets.Count
With Sheets(WkSht)
.Unprotect "mypassword"
End With
Next WkSht
End Sub

 

[Von Pookie]

You can use an inputbox to get the value from the user and save it as a variable:

Sub LockFormulas()
Dim WkSht As Worksheet, strPass As String

strPass = InputBox("Enter the password to continue.")
If strPass = "" Then Exit Sub

For Each WkSht In ThisWorkbook.Worksheets
    With WkSht
        On Error Resume Next
        .Cells.Locked = False
        .Cells.SpecialCells(xlCellTypeFormulas, 23).Locked = True
        .Protect strPass
        Err.Clear
    End With
Next WkSht

End Sub



Sub UnlockFormulas()
Dim WkSht As Worksheet, strPass As String

strPass = InputBox("Enter the password to continue.")
If strPass = "" Then Exit Sub

For Each WkSht In ThisWorkbook.Worksheets
    WkSht.Unprotect strPass
Next WkSht

End Sub

Note that the code I posted above does not include error trapping. If you enter an incorrect password, an error will occur.

 

[andyreloaded]

Thanks so much, that works flawlessly. I gotta learn me some VB.