Macro for renaming a certain file type only

[Life4Music]

Hello everyone.
Just joined here
Wanted to ask for a macro that renames only certain file types in a folder. I want this for a certain file types, as the files I am looking to rename have the today's date in them, so the name changes everyday.
Example - I have 7 SPSS files (.sav) which I want to rename - screenshot below is how they are downloaded so raw names. You'll notice that they have (1), (2) etc i hope this isnt an issue for the macro?

Each of the files corresponds to a certain market - so the one which is panel_data_2022_09_15 - AU , panel_data_2022_09_15 (1) - CN , etc.
I want each file so for instance the (1) file , to be named to CN + apply today's date as such - "_20220915" (no " in the new name)

Can someone help me with this? Is it possible to do ?

 

[johnnyL]

Is there a space before the (*) in the file name? If so, that would explain the problem.

 

[johnnyL]

This will account for the space, if that is the issue:

Sub RenameFiles()
'
    Dim PathToFiles                 As String
    Dim FileNameWithExtension       As String
    Dim NewFileNameWithExtension    As String
'
    PathToFiles = "C:\Users\" & Environ("UserName") & "\Downloads\"                                                     ' Set this to the path of the folder to look through, Path needs to end with '\' ;)
'
    FileNameWithExtension = Dir(PathToFiles & "*.sav")                                                                  ' Get first .sav file name with extension
'
    Do While Len(FileNameWithExtension) > 0                                                                             ' Loop to cycle through all files in the specified folder
        If (Right(FileNameWithExtension, 3) = "sav") And (Left(FileNameWithExtension, 11) = "panel_data_") Then         '   If we find a file that we want to rename then ...
            NewFileNameWithExtension = Replace(Mid$(FileNameWithExtension, 12), "_", "")                                '       Remove 'panel_data' and any other '_' from the FileNameWithExtension
'
            If InStr(1, NewFileNameWithExtension, "(") = 0 Then                                                         '       If the NewFileNameWithExtension doesn't contain a '(' then ...
                NewFileNameWithExtension = "AU_" & NewFileNameWithExtension                                             '           Append the identifier to the beginning of the NewFileNameWithExtension
            Else                                                                                                        '       Else ...
                Select Case Mid$(NewFileNameWithExtension, 11, 1)                                                       '           Determine which identifer needs to be appended to NewFileNameWithExtension
                    Case Is = "1": NewFileNameWithExtension = "CN_" & Replace(NewFileNameWithExtension, " (1)", "")
                    Case Is = "2": NewFileNameWithExtension = "DE_" & Replace(NewFileNameWithExtension, " (2)", "")
                    Case Is = "3": NewFileNameWithExtension = "IT_" & Replace(NewFileNameWithExtension, " (3)", "")
                    Case Is = "4": NewFileNameWithExtension = "JP_" & Replace(NewFileNameWithExtension, " (4)", "")
                    Case Is = "5": NewFileNameWithExtension = "ES_" & Replace(NewFileNameWithExtension, " (5)", "")
                    Case Is = "6": NewFileNameWithExtension = "US_" & Replace(NewFileNameWithExtension, " (6)", "")
                End Select
            End If
'
            Name PathToFiles & FileNameWithExtension As PathToFiles & NewFileNameWithExtension                          '       Rename the file to the NewFileNameWithExtension
        End If
'
        FileNameWithExtension = Dir                                                                                     '   Check for additional files to rename
    Loop                                                                                                                ' Loop back
'
    MsgBox "Renaming process complete!"                                                                                 ' Inform the user that script has finished
End Sub

 

[Life4Music]

ah yes - there are spaces infront of the (1) (2) and so on.

so the files are actually panel_data_2022_09_15 (1) ... etc
Which part do i need to change?

 

[Life4Music]

I didn't see your second message - yes it worked perfectly with the second macro !
I cannot express how thankful i am , macro is really interesting and cool !
If you ever come to Bulgaria , hit me up on the DMs i will buy you a beer :D

 

[johnnyL]

Glad to help & welcome to the site.