Macro running in one computer but not running in another computer

[John1989]

Hi,

I need to send a data in the excel to various persons through Outlook app in PDF format. So I am using the following VBA code. This works fine in my computer. But it is not running in another computer and showing " Run time error 5, Invalid Procedure call or argument". In both system, we are using Excel 2007 version. Please help.

Sub AttachActiveSheetPDF()
Dim IsCreated As Boolean
Dim i As Long
Dim PdfFile As String, Title As String
Dim OutlApp As Object

' Not sure for what the Title is
Title = Range("A1")

' Define PDF filename
PdfFile = ActiveWorkbook.FullName
i = InStrRev(PdfFile, ".")
If i > 1 Then PdfFile = Left(PdfFile, i - 1)
PdfFile = PdfFile & "_" & ActiveWorkbook.Sheets("Email").Range("C1").Value & ".pdf"

' Export activesheet as PDF
With ActiveSheet
.ExportAsFixedFormat Type:=xlTypePDF, Filename:=PdfFile, Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
End With

' Use already open Outlook if possible
On Error Resume Next
Set OutlApp = GetObject(, "Outlook.Application")
If Err Then
Set OutlApp = CreateObject("Outlook.Application")
IsCreated = True
End If
OutlApp.Visible = True
On Error GoTo 0

' Prepare e-mail with PDF attachment
With OutlApp.CreateItem(0)

' Prepare e-mail
.Subject = Title
.To = ActiveWorkbook.Sheets("Email").Range("B1")
.CC = ActiveWorkbook.Sheets("Email").Range("B2")
.Subject = ActiveWorkbook.Sheets("Email").Range("B4")
.Body = ActiveWorkbook.Sheets("Email").Range("B5")
.Attachments.Add PdfFile

' Try to send
On Error Resume Next
.Send
Application.Visible = True
If Err Then
MsgBox "E-mail was not sent", vbExclamation
Else
MsgBox "E-mail successfully sent", vbInformation
End If
On Error GoTo 0

End With

' Delete PDF file
Kill PdfFile

' Quit Outlook if it was created by this code
If IsCreated Then OutlApp.Quit

' Release the memory of object variable
Set OutlApp = Nothing

End Sub

 

[RoryA]

Do both systems have at least Office 2007 Service Pack 2 applied?

Which line is causing the error?

 

[John1989]

Both system have 2007 service pack. I actually don't know where error starts.. When I click the macro button it shows the error

 

[RoryA]

Do you not get a Debug option when the error occurs?

 

[John1989]

Now I installed the SaveAsPDF add for MS Office 2007 in that PC. Now it is working fine. Thanks all..

 

[RoryA]

Than you didn't have Service Pack 2 installed on that computer (and you really should). SP2 removed the need for a separate add-in to export to PDF.