Macro running on every sheet

[KarlP]

How can I make this macro run in any worksheet. For now it runs only if the sheet name is "Sheet1 (2)"
I am a beginner and very happy to have created this macro. Now I would like it to work all the time

Sub TricolonneC()
'
' TricolonneC Macro
'
' Touche de raccourci du clavier: Ctrl+t
'
    Range(Selection, Selection.End(xlDown)).Select
    Range(Selection, Selection.End(xlToRight)).Select
    ActiveWorkbook.Worksheets("Sheet1 (2)").Sort.SortFields.Clear
    ActiveWorkbook.Worksheets("Sheet1 (2)").Sort.SortFields.Add2 Key:=ActiveCell. _
        Offset(0, 1).Range("A1:A5"), SortOn:=xlSortOnValues, Order:=xlAscending, _
        DataOption:=xlSortNormal
    With ActiveWorkbook.Worksheets("Sheet1 (2)").Sort
        .SetRange ActiveCell.Range("A1:B5")
        .Header = xlGuess
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
End Sub

 

[Fluff]

Hi & welcome to MrExcel.
How about

Sub TricolonneC()
'
' TricolonneC Macro
'
' Touche de raccourci du clavier: Ctrl+t
'
   Range(Selection, Selection.End(xlDown)).Select
   Range(Selection, Selection.End(xlToRight)).Select
   With ActiveSheet.Sort
      .SortFields.clear
      .SortFields.Add2 Key:=ActiveCell.Offset(0, 1).Range("A1:A5"), SortOn:=xlSortOnValues, Order:=xlAscending, _
            DataOption:=xlSortNormal
      .SetRange ActiveCell.Range("A1:B5")
      .Header = xlGuess
      .MatchCase = False
      .Orientation = xlTopToBottom
      .SortMethod = xlPinYin
      .Apply
   End With
End Sub

 

[KarlP]

Thanks it's now working on any sheet but it sort only the five first line even if the macro selected many more lines
I've upload an image. You can see that the selection is from B96 to C115 but the sorting occured only from 96 to 100
I guess it's about range that is fix A1:B5. How do we make it variable so it sort all of the selected cells

 

[Fluff]

Ok, how about

Sub TricolonneC()
'
' TricolonneC Macro
'
' Touche de raccourci du clavier: Ctrl+t
'
   Range(Selection, Selection.End(xlDown)).Select
   Range(Selection, Selection.End(xlToRight)).Select
   With ActiveSheet.Sort
      .SortFields.clear
      .SortFields.Add2 Key:=ActiveCell.Offset(0, 1), SortOn:=xlSortOnValues, Order:=xlAscending, _
            DataOption:=xlSortNormal
      .SetRange Selection
      .Header = xlGuess
      .MatchCase = False
      .Orientation = xlTopToBottom
      .SortMethod = xlPinYin
      .Apply
   End With
End Sub

 

[KarlP]

Works perfectly
Thanks

 

[Fluff]

You're welcome & thanks for the feedback.