Macro to change numbers after decimal point

[ste33uka]

Hi would anyone have a macro that would randomly change the numbers after a decimal point,
for a worksheet called data and would apply to range c2:c20,
this is what column c looks like

 

[lrobbo314]

How about this?

Sub changeDec()
Dim ws As Worksheet:    Set ws = Sheets("data")
Dim r As Range:         Set r = ws.Range("C2:C20")
Dim AR() As Variant:    AR = r.Value2

For i = LBound(AR) To UBound(AR)
    AR(i, 1) = Int(AR(i, 1)) + Rnd()
Next i
    
r.Value2 = AR
End Sub

 

[ste33uka]

How about this?

Sub changeDec()
Dim ws As Worksheet:    Set ws = Sheets("data")
Dim r As Range:         Set r = ws.Range("C2:C20")
Dim AR() As Variant:    AR = r.Value2

For i = LBound(AR) To UBound(AR)
    AR(i, 1) = Int(AR(i, 1)) + Rnd()
Next i
   
r.Value2 = AR
End Sub

sorry got it a bit wrong numbers are in percentage.
Could you adjust code for that please.

 

[ste33uka]

also is it possible if cell is blank it would remain blank?

 

[ER_Neha]

Hello Please Try this

Sub random_number()
    
    Dim i As Double
    Dim r As Double
    Dim cell As Range
    
    For Each cell In Range("c2:c20").Cells
        r = cell.Value
        i = Int(cell.Value)
        r = r - i
        r = Rnd(r)
        cell.Value = i + r
    
    Next cell


End Sub

 

[lrobbo314]

This should do it.

Sub changeDec()
Dim ws As Worksheet:    Set ws = Sheets("data")
Dim r As Range:         Set r = ws.Range("C2:C20")
Dim AR() As Variant:    AR = r.Value2

For i = LBound(AR) To UBound(AR)
    AR(i, 1) = (Int(AR(i, 1) * 100) + Rnd()) / 100
Next i
    
r.Value2 = AR
End Sub

 

[Fluff]

Borrowing lrobbo's code

Sub changeDec()
Dim ws As Worksheet:    Set ws = Sheets("data")
Dim r As Range:         Set r = ws.Range("C2:C20")
Dim i As Long
Dim AR() As Variant:    AR = r.Value2
Randomize
For i = LBound(AR) To UBound(AR)
   If AR(i, 1) <> "" Then
      AR(i, 1) = (Int(AR(i, 1) * 100) + Rnd()) / 100
   End If
Next i
   
r.Value2 = AR
End Sub

 

[ste33uka]

thanks irobbo and fluff
Job done, thanks

 

[Fluff]

Glad we (mainly lrobbo ) could help & thanks for the feedback.