Macro To Compare Sheets and Highlight Common

[gaspower]

Hello,
I use the below to highlight similar between two sheets,

Sub GreenDifference()
Dim LR As Long, i As Long, x As Variant
LR = Sheets("Sheet1").Range("A" & Rows.Count).End(xlUp).Row
For i = 1 To LR
    x = Application.Match(Sheets("Sheet1").Range("A" & i).Value, Sheets("Sheet2").Columns("A"), 0)
    If IsNumeric(x) Then
        Sheets("Sheet1").Range("A" & i).Interior.Color = vbGreen
        Sheets("Sheet2").Range("A" & x).Interior.Color = vbGreen
    End If
Next i
End Sub

I would like to compare on more than two sheets, and the amount of sheets may vary. Can someone please help in allowing the code to expand over many sheets.

Thank you

EDIT
Also posted here Macro To Compare Sheets and Highlight Common

 

[Fluff]

Do you want to highlight col A on sheet 1 if it matches col A in any other sheet?

 

[gaspower]

Hello,
I have also cross posted here. Cross Post

 

[gaspower]

Hello Fluff,

That is correct. Thank you

 

[Fluff]

Ok, how about

Sub gaspower()
   Dim Ary As Variant
   Dim i As Long
   Dim Ws As Worksheet, Ws1 As Worksheet
   Dim Cl As Range
   
   Set Ws1 = Sheets("Sheet1")
   With CreateObject("scripting.dictionary")
      .CompareMode = 1
      For Each Ws In Worksheets
         If Not Ws.Name = Ws1.Name Then
            Ary = Ws.Range("A1", Ws.Range("A" & Rows.Count).End(xlUp)).Value2
            If IsEmpty(Ary) Then Exit For
            For i = 1 To UBound(Ary)
               .Item(Ary(i, 1)) = Empty
            Next i
         End If
      Next Ws
      For Each Cl In Ws1.Range("A1", Ws1.Range("A" & Rows.Count).End(xlUp))
         If .Exists(Cl.Value) Then Cl.Interior.Color = vbGreen
      Next Cl
   End With
End Sub