Macro to insert a jpg from file in specific location on a worksheet

[gmmom00]

All,
I am trying to write a macro to take a logo in a file logo.jpg and insert it into to the top left corner of each of three worksheets in a workbook. Not in a header, just in the upper left corner of the worksheets. Is this possible? Does the jpg of the logo have to be somewhere else in the workbook or in another open excel file? Normally I make my macros by recording and then clean up the code. Can I record this marcro?
Thanks,
h

 

[Tom Urtis]

The top left corner of every worksheet is cell A1. I'm sure you know that, so maybe by "top left corner" you mean whichever cell happens to be in the visible top left corner at any given time. If so, that would not give much structure to your workbook design, seeing as that visible top left cell could be one of millions of cells at the time of macro execution, thereby placing your logo file in unpredictable locales...not a good idea.

Be that as it may, assuming...

• You want the picture in cell A1
• The picture is named logo.jpg
• The picture resides on your C drive in the folder named YourFilePath
• The three destination worksheets are named Sheet1, Sheet2, and Sheet3

...this works, just tested no problem:

Sub Test1()
Dim sFile As String
sFile = "C:\YourFilePath\logo.jpg"

If Dir(sFile) = "" Then
MsgBox "Picture file was not found in path!", , "No such animal"
Exit Sub
End If

Dim pct As Picture, iLeft#, iTop#
Dim SheetList As Variant, SheetItem As Variant
SheetList = Array("Sheet1", "Sheet2", "Sheet3")

For Each SheetItem In SheetList
With Sheets(SheetItem)
With .Range("A1")
iLeft = .Left: iTop = .Top
End With
Set pct = .Pictures.Insert(sFile)
pct.Left = iLeft
pct.Top = iTop
End With
Next SheetItem 
End Sub

 

[gmmom00]

Tom,
Thank-you for your reply, and all your assumptions were correct, especially A1. Thank-you, I will try this and let you know if I have any additional questions.
So much appreciated!
h

 

[gmmom00]

Worked Perfect, Thanks again Tom!