Macro to page down every 5 minutes?

[Hydra427]

Can someone help me with the code to automatically page down every 5 minutes until the last record is reached and then return to the top and start over. I have a spreadsheet that automatically updates (refreshes) every 15 minutes and want it to automatically page down every 5 minutes so that the shop can see the latest inventory to pull.

 

[Hydra427]

All right, I have figured out how to page down every :30 but need to to repeat the page down until it reaches the last record and then return to the first record and continue. This must also work as the spreadsheet automatically refreshes every 15 minutes. Here is the code I am using to page down.

Sub Macro1()
'
' Macro1 Macro
'
'
Range("A1").Select
Application.Wait (Now + TimeValue("0:00:30"))
ActiveWindow.LargeScroll Down:=1


End Sub

 

[John_w]

Try this code in a standard module. It looks in column A to determine the last row, so change the "A" in the code to use a different column.

Option Explicit

Public RunWhen As Double

Public Sub StartTimer()
    RunWhen = Now + TimeValue("00:00:30")
    Application.OnTime EarliestTime:=RunWhen, Procedure:="Page_Down", Schedule:=True
End Sub

Public Sub StopTimer()
    On Error Resume Next
    Application.OnTime EarliestTime:=RunWhen, Procedure:="Page_Down", Schedule:=False
End Sub

Public Sub Page_Down()

    Dim lastRow As Long
    
    lastRow = Cells(Rows.Count, "A").End(xlUp).Row
    ActiveWindow.LargeScroll Down:=1
    If ActiveWindow.ScrollRow > lastRow Then ActiveWindow.ScrollRow = 1
    
    StartTimer
        
End Sub

Run or call StopTimer to stop the scrolling (e.g. from a command button), and put this code in the ThisWorkbook module to stop the timer when you close the workbook:

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    StopTimer
End Sub