Macro to populate date when there is a change in the cell/Row

[petes]

I need to alter this code so that, only when there is change in RowID 5, the date should be populated. Currently, the date is populating whenever the cursor comes to that row (irrespective of changes).

Also, I need this for 1000 Rows (from D5 to D1000)

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If (Target.Row = 5) Then
range("D5").formula="=today()"

End If
End Sub

 

[VoG]

Perhaps like this

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Row >= 5 And Target.Row <= 1000 Then
    Application.EnableEvents = False
    Cells(Target.Row, 4).Value = Date
    Application.EnableEvents = True
End If
End Sub

 

[petes]

This is exactly what i wanted, but now i need some further improvements--

The date should be populated only if the specific cells gets changed.
Those specific cells are A5, C5, E5, F5, J5 (Similarly for rest 1000 cells)

 

[VoG]

Try

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Row >= 5 And Target.Row <= 1000 Then
    If Target.Column = 1 Or Target.Column = 3 Or Target.Column = 5 Or Target.Column = 6 Or Target.Column = 10 Then
        Application.EnableEvents = False
        Cells(Target.Row, 4).Value = Date
        Application.EnableEvents = True
    End If
End If
End Sub

 

[petes]

yet again, thanks a bunch!!

 

[Weaver]

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Row >= 5 And Target.Row <= 1000 Then
        Select Case Target.Column
            Case 1, 3, 5, 6, 10
                Application.EnableEvents = False
                Cells(Target.Row, "D").Value = Date
        End Select
    End If
safeExit:
    Application.EnableEvents = True
End Sub