Macro to split my data up into 5 rows per order

[tonywatsonhelp]

Hi Everyone,

I need a macro to do the following,

I have data in activesheet range A2:AZ last row

Each row has an order number in column A

I Have Another sheet Call "OUTPUT"

Now I dont need every Column copied over Just these ones

A,C,F,V:AE

so
A to A
C to B
F to C
V to D and so on


But this is what i do need,
Each row has data in columns Q:U (5 columns)
I want to make 5 identical rows Just with Column N holding one of the 5 data from Q:U (5 columns)

so i get 5 rows all the same but showing whats in columns Q to U as individual rows

hope thats nice and clear,
please help if you can

Thanks

Tony

 

[Fluff]

How about

Sub tonywatsonhelp()
   Dim Ary As Variant, Nary As Variant
   Dim r As Long, c As Long, cc As Long, nr As Long
   
   With Sheets("Sheet1")
      Ary = .Range("A2:AE" & .Range("A" & Rows.Count).End(xlUp).Row).Value2
   End With
   ReDim Nary(1 To UBound(Ary) * 5, 1 To 14)
   For r = 1 To UBound(Ary)
      For c = 1 To 5
         nr = nr + 1
         Nary(nr, 1) = Ary(r, 1)
         Nary(nr, 2) = Ary(r, 3)
         Nary(nr, 3) = Ary(r, 6)
         For cc = 1 To 10
            Nary(nr, cc + 3) = Ary(r, cc + 21)
         Next cc
         Nary(nr, 14) = Ary(r, c + 16)
      Next c
   Next r
   Sheets("Sheet2").Range("A2").Resize(nr, 14).Value = Nary
End Sub

 

[tonywatsonhelp]

Thank you fluff,
this is once again amazing
Thank you so much
Tony

 

[Fluff]

Glad to help & thanks for the feedback.