macro vba delete first row of all sheets except some

[tuytuy]

Hi,
i wanted to right a vba that would delete the first row all all the sheets except 3 ("SynthesisVSD" And "BlackBerry" And "Table_Of_Content")

Here is what i wrote but i get a type mismatch:

'Deleting first row


For Each Worksheet In ThisWorkbook.Worksheets
Namews = Array("SynthesisVSD", _
              "BlackBerry", _
              "Table_Of_Content")
If Worksheet.Name = Namews Then
            With Worksheet.UsedRange
                Worksheet.Rows(1).Delete
            End With
        End If


Next

 

[VoG]

Try

'Deleting first row

namews = Array("SynthesisVSD", _
              "BlackBerry", _
              "Table_Of_Content")

For Each ws In ThisWorkbook.Worksheets
    If IsError(Application.Match(ws.Name, namews, 0)) Then ws.Rows (1), Delete
Next ws

 

[tuytuy]

i get an error "object doesn't support this property or method" ?

 

[VoG]

Typo

'Deleting first row

namews = Array("SynthesisVSD", _
              "BlackBerry", _
              "Table_Of_Content")

For Each ws In ThisWorkbook.Worksheets
    If IsError(Application.Match(ws.Name, namews, 0)) Then ws.Rows(1).Delete
Next ws

 

[tuytuy]

still doesn't work :/ nothing happens.
Is this bit correct ?

ws.Rows(1).Delete

 

[kevatarvind]

try below one

Sub Test()
Dim ws As Worksheet
For Each ws In ThisWorkbook.Worksheets
If ws.Name <> "SynthesisVSD" And ws.Name <> "BlackBerry" And ws.Name <> "Table_Of_Content" Then ws.Rows(1).Delete
Next ws
End Sub

 

[VoG]

still doesn't work :/ nothing happens.
Is this bit correct ?

ws.Rows(1).Delete

Tested and working here.

 

[Rick Rothstein]

Here is another macro you can try...

Sub DeleteFirstRowCertainSheets()
  Dim WS As Worksheet
  For Each WS In ThisWorkbook.Worksheets
    If InStr(1, "/SynthesisVSD/BlackBerry/Table_Of_Content/", "/" & _
         WS.Name & "/", vbTextCompare) = 0 Then WS.Rows(1).Delete
  Next
End Sub

 

[Peter_SSs]

Yet another possibility

Sub Delete_Row()
  Dim ws As Worksheet
  
  For Each ws In Worksheets
    Select Case ws.Name
      Case "SynthesisVSD", "BlackBerry", "Table_Of_Content" '<- Add more if you want
      Case Else
        ws.Rows(1).Delete
    End Select
  Next ws
End Sub