Macros for How to find a specific word then bold the 2 cells underneath it

[Pr0x1mo]

Example, this is all in one column by the way, but it would look like this

A5 Total Amount:
A6 107,424,873.26
A7 88

"Total Amount" can be in random areas but i just want a macros to find that word then to bold the proceeding 2 cells underneath it.

 

[hiker95]

Pr0x1mo,

Here is a macro solution for you to consider, based on the description of your raw data.

Please TEST this FIRST in a COPY of your workbook (always make a backup copy before trying new code, you never know what you might lose).

1. Copy the below code
2. Open your NEW workbook
3. Press the keys ALT + F11 to open the Visual Basic Editor
4. Press the keys ALT + I to activate the Insert menu
5. Press M to insert a Standard Module
6. Where the cursor is flashing, paste the code
7. Press the keys ALT + Q to exit the Editor, and return to Excel
8. To run the macro from Excel press ALT + F8 to display the Run Macro Dialog. Double Click the macro's name to Run it.

Sub FindTotalAmount()
' hiker95, 06/01/2015, ME858477
Dim c As Range, firstaddress As String
Application.ScreenUpdating = False
With ActiveSheet.Columns(1)
  Set c = .Find("Total Amount:", LookIn:=xlValues, LookAt:=xlWhole)
  If Not c Is Nothing Then
    firstaddress = c.Address
    Do
      c.Offset(1).Resize(2).Font.Bold = True
      Set c = .FindNext(c)
    Loop While Not c Is Nothing And c.Address <> firstaddress
  End If
End With
End Sub

Before you use the macro with Excel 2007 or newer, save your workbook, Save As, a macro enabled workbook with the file extension .xlsm, and, answer the "do you want to enable macros" question as "yes" or "OK" (depending on the button label for your version of Excel) the next time you open your workbook.

Then run the FindTotalAmount macro.