Make some CheckBoxes in one Form behavie according to a ListBox of another Form

[davileal]

Hey, guys.

I put some CheckBoxes in my Form and make all of them invisible. Then I want to make only a few of them visible according to the number of Itens that the 'User' insert on a ListBox from the past Form. I also want to change the captions of these CheckBox to the same name of the itens of the ListBox.

I try this:

Private Sub UserForm_Activate()
    
            If IsNull(UserForm2.ListBox1.List(0)) Then
                CheckBox1.Visible = False
            Else:
                CheckBox1.Caption = UserForm2.ListBox1.List(0)
            End If
            
            
            If IsNull(UserForm2.ListBox1.List(1)) Then
                CheckBox2.Visible = False
            Else:
                CheckBox2.Caption = UserForm2.ListBox1.List(1)
            End If

            ...
End Sub

The CheckBoxex go until 20. My problem is: If the number of the ListBox itens is 10, I have trouble with the code UserForm2.ListBox1.List(10).

I'm a noob on VBA. Please give me some light. Thanks advance.

 

[Yongle]

Try this method
- it uses loops to avoid repeating the code for each checkbox

Two subs are called from UserForm_Activate
- ONE to hide all checkboxes and the OTHER to make some visible with caption matching item in Listbox1 in UserForm2

Private Sub UserForm_Activate()
    Call HideCheckBoxes
    Call ShowCheckBoxes
End Sub

Private Sub HideCheckBoxes()
    Dim c As Control
    For Each c In Me.Controls
        If TypeName(c) = "CheckBox" Then c.Visible = False
    Next
End Sub

Private Sub ShowCheckBoxes()
    Dim c As Control, x As Long
    With UserForm2.listbox1
        For x = 1 To .ListCount
            For Each c In Me.Controls
                If c.Name = "CheckBox" & x Then
                    c.Visible = True
                    c.Caption = .List(x - 1)
                    Exit For
                End If
            Next c
        Next x
    End With
End Sub

The code should not fail even if the listbox is empty

 

[davileal]

Thanks, man.

Works Fine.