Merge Multiple Sheets

[unknownymous]

Hi Guys,

Happy New year!

I found below code however, it seems like only column A of each sheet is being copied on the combined Sheet. Is it possible to adjust the range and copy everything except Row 1 for each sheet?

= = = = =

Sub Combine_Sheets()

Dim startRow, startCol, LastRow, lastCol As Long
Dim headers As Range

'Set Master sheet for consolidation
Set mtr = Worksheets("Combined")

Set wb = ThisWorkbook
'Get Headers
Set headers = Application.InputBox("Select the Headers", Type:=8)

'Copy Headers into master
headers.Copy mtr.Range("A1")
startRow = headers.Row + 1
startCol = headers.Column

Debug.Print startRow, startCol
'loop through all sheets
For Each ws In wb.Worksheets
'except the master sheet from looping
If ws.Name <> "Combined" Then
ws.Activate
LastRow = Cells(Rows.Count, startCol).End(xlUp).Row
lastCol = Cells(startRow, Columns.Count).End(xlToLeft).Column
'get data from each worksheet and copy it into Master sheet
Range(Cells(startRow, startCol), Cells(LastRow, lastCol)).Copy _
mtr.Range("A" & mtr.Cells(Rows.Count, 1).End(xlUp).Row + 1)
End If
Next ws

Worksheets("Combined").Activate

End Sub

Any help will be much appreciated.

Regards!

= = =
Source: Consolidate/Merge multiple worksheets into one master sheet using VBA
= = =

 

[Peter_SSs]

it seems like only column A of each sheet is being copied

.. but did you try it to check?

 

[unknownymous]

Yes, I did.

I have one sheet that has format like this so I'm not quite sure if this has to do with the format.

Name
Number 1
Number 2		Owen G
Number 3
Number 4	St Louie
Number 5			PO Box 2000
Number 6				Ohio
Number 7					Note

Thank you!

 

[Peter_SSs]

Yes, I did.

OK. The problem is that the code uses the headings to determine the columns to copy and since you only have one heading ...

Try this instead. It assumed the 'Combined' sheet exists but has nothing in it.

Sub Combine_Sheets_v2()
  Dim ws As Worksheet
  Dim nr As Long
  
  nr = 1
  For Each ws In Worksheets
    If ws.Name <> "Combined" Then
      With ws.UsedRange
        .Offset(IIf(nr = 1, 0, 1)).Copy Destination:=Sheets("Combined").Range("A" & nr)
        nr = nr + .Rows.Count - IIf(nr = 1, 0, 1)
      End With
    End If
  Next ws
End Sub

 

[unknownymous]

OK. The problem is that the code uses the headings to determine the columns to copy and since you only have one heading ...

Try this instead. It assumed the 'Combined' sheet exists but has nothing in it.

Sub Combine_Sheets_v2()
  Dim ws As Worksheet
  Dim nr As Long
 
  nr = 1
  For Each ws In Worksheets
    If ws.Name <> "Combined" Then
      With ws.UsedRange
        .Offset(IIf(nr = 1, 0, 1)).Copy Destination:=Sheets("Combined").Range("A" & nr)
        nr = nr + .Rows.Count - IIf(nr = 1, 0, 1)
      End With
    End If
  Next ws
End Sub

It's working! One thing, there's an available headers already in the Combine Sheet tab. Is it possible to adjust the code as it seems like the existing headers were deleted.

 

[Peter_SSs]

.. there's an available headers already in the Combine Sheet tab. Is it possible to adjust the code ..

In that case the code is even simpler ..

Sub Combine_Sheets_v3()
  Dim ws As Worksheet
  
  For Each ws In Worksheets
    If ws.Name <> "Combined" Then ws.UsedRange.Offset(1).Copy Destination:=Sheets("Combined").Range("A" & Rows.Count).End(xlUp).Offset(1)
  Next ws
End Sub

 

[unknownymous]

tHANK YOU

In that case the code is even simpler ..

Sub Combine_Sheets_v3()
  Dim ws As Worksheet
 
  For Each ws In Worksheets
    If ws.Name <> "Combined" Then ws.UsedRange.Offset(1).Copy Destination:=Sheets("Combined").Range("A" & Rows.Count).End(xlUp).Offset(1)
  Next ws
End Sub

Thank you!

 

[Peter_SSs]

You are welcome. Thanks for the follow-up.