Message Input Box for Macro

[ilcaa]

I have a macro that deletes repetitive rows. this one shows for Column E, if I want to change to look for items in column C I need to manually go to the macro editior and change it...I wanted a input box to show asking which column, then it would change the column letter in the macro accordingly....hope i made sense, please let me know if you have a solution...

=Sub DELETE_ADDRESSES()
For MY_ROWS = Range("E65536").End(xlUp).Row To 2 Step -1
If Range("E" & MY_ROWS).Value = Range("E" & MY_ROWS - 1).Value Then
Rows(MY_ROWS - 1).Delete
End If
Next MY_ROWS
End Sub

 

[VoG]

Try this

Sub DELETE_ADDRESSES()
Dim r As Range, i As Long, j As Integer
On Error Resume Next
Set r = Application.InputBox("Click in the column", Type:=8)
On Error GoTo 0
If r Is Nothing Then Exit Sub
j = r.Column
For i = Cells(Rows.Count, j).End(xlUp).Row To 2 Step -1
    If Cells(i, j).Value = Cells(i - 1, j).Value Then
        Rows(i - 1).Delete
    End If
Next i
End Sub

 

[onlyadrafter]

Hello,

If you want to type in a column try

Sub DELETE_ADDRESSES()
    MY_COL = InputBox("Which column?", "DATA ENTRY")
    For MY_ROWS = Range(MY_COL & "65536").End(xlUp).Row To 2 Step -1
        If Range(MY_COL & MY_ROWS).Value = Range(MY_COL & MY_ROWS - 1).Value Then
            Rows(MY_ROWS - 1).Delete
    End If
    Next MY_ROWS
End Sub

this has no error checking though.

 

[ilcaa]

they both work perfectly...

thanks.