Mid Find function with 2 variables

[trankim]

Hi,
I am trying to create a formula that will search for either a ">" or "_" and return the text after the 1st "_" or ">". In other words, how can I combine the below two formulas so that it searches for either "_" or ">".

formulas:
=MID($Z5,FIND(">",$Z5)+1,LEN($Z5))
=MID($Z5,FIND("_",$Z5)+1,LEN($Z5))

Text Examples:
us_Sales_Forms_test_en should return Sales_Forms_test_en
US>Sales>>>Forms>>survey should return "Sales>>>Forms>>survey

Thank you for any help that you can provide.

 

[Marcelo Branco]

Maybe something like that

=MID($Z5,1+MIN(FIND({"_";">"},$Z5&"_"&">")),LEN($Z5))

M.

 

[trankim]

Thank YOU! It worked beautifully!!!!

 

[Marcelo Branco]

Or better

=IF(OR(ISNUMBER(FIND("_",Z5)),ISNUMBER(FIND(">",Z5))),MID(A1,1+MIN(FIND({"_";">"},Z5&"_"&">")),LEN(Z5)),Z5)

M.

 

[Marcelo Branco]

Thank YOU! It worked beautifully!!!!

You are welcome and thanks for the feedback

M.

 

[trankim]

That worked too when I changed the "A1" in your formula to "Z5", but forgive me if I don't understand the difference between the two and why the 2nd one is better? I would think the first one since it's shorter? I appreciate your thoughts for learning purposes.

 

[Rick Rothstein]

One more for you to consider...

=REPLACE($Z5,1,FIND("_",SUBSTITUTE($Z5,">","_")&"_"),"")

 

[Marcelo Branco]

That worked too when I changed the "A1" in your formula to "Z5", but forgive me if I don't understand the difference between the two and why the 2nd one is better? I would think the first one since it's shorter? I appreciate your thoughts for learning purposes.

If the text has neither "_" nor ">" the first formula returns "" (blank)

The second returns the original text.

M.
ps: thank you for changing A1 to Z5 - i was making tests using A1 and forgot to change when i posted.