modification Code vba

[sofas]

Welcome . How can I search in sheet2 only because the code searches all sheets

Private Sub TextBox1_Change()
If TextBox1.Value = "" Then ListBox2.Clear: Exit Sub
Dim x As Worksheet
         ListBox2.Clear
    k = 0
For Each x In ThisWorkbook.Worksheets
        ss = x.Cells(Rows.Count, 3).End(xlUp).Row
        For Each c In x.Range("c2:c" & ss)
            b = InStr(c, TextBox1)
            If b > 0 Then
                ListBox2.AddItem
                ListBox2.List(k, 0) = x.Cells(c.Row, 3).Value
                

                k = k + 1
            End If
        Next c

Next x
End Sub

 

[Joe4]

Get rid of your loop:

For Each x In ThisWorkbook.Worksheets

and corresponding:

Next x

line.

And then add this line at the top:

Set x = Sheets("Sheet2")

 

[DanteAmor]

I simplified your code a bit:

Private Sub TextBox1_Change()
  Dim c As Range
  
  ListBox2.Clear
  If TextBox1.Value = "" Then Exit Sub
  With Sheets("Sheet2")
    For Each c In .Range("C2", .Cells(Rows.Count, 3).End(xlUp))
      If InStr(c.Value, TextBox1) > 0 Then
        ListBox2.AddItem c.Value
      End If
    Next c
  End With
End Sub