Move values from columns to new rows

[BioPA]

Hello everybody!

I 'd appreciate if somebody helped me on this:

I have N rows of data separated into 4 columns

	A	B	C	D
1	VALUE1i	VALUE1ii	VALUE1iii	VALUE1iv
2	VALUE2i	VALUE2ii	VALUE2iii	VALUE2iv
3	VALUE3i	VALUE3ii	VALUE3iii	VALUE3iv
N	VALUENi	VALUENii	VALUENiii	VALUENiv

<tbody>
</tbody>

I would like to take the values from C and D columns and move them behind
the first 2, so that

	A	B
1	VALUE1i	VALUE1ii
2	VALUE1iii	VALUE1iv
3	VALUE2i	VALUE2ii
4	VALUE2iii	VALUE2iv
5	VALUE3i	VALUE3ii
6	VALUE3iii	VALUE3iv
7	VALUENi	VALUENii
8	VALUENiii	VALUENiv

<tbody>
</tbody>

So, now we have 2 columns, 2 new inserted rows with the cell values from column C & D.

Is it possible to have a macro for that?

 

[Akuini]

Maybe this:

Sub a939920()
Dim va, vc, i As Long, j As Long

va = Range("A1", Cells(Rows.count, "D").End(xlUp)).Value
ReDim vc(1 To UBound(va, 1) * 2, 1 To 2)
j = 1
For i = 1 To UBound(va, 1)
    vc(j, 1) = va(i, 1)
    vc(j, 2) = va(i, 2)
    vc(j + 1, 1) = va(i, 3)
    vc(j + 1, 2) = va(i, 4)
    j = j + 2
Next
Range("A1", Cells(Rows.count, "D").End(xlUp)).ClearContents
Range("A1").Resize(UBound(va, 1) * 2, 2) = vc

End Sub

 

[BioPA]

Awesome. Quality and fast response.

Thank you very much!

 

[Akuini]

Awesome. Quality and fast response.

Thank you very much!

You're welcome & thanks for the reply