MsgBox yes/no options to continue ot stop

[ipbr21054]

I am using the code below.

I start to type a name in Textbox1 & the results starts to appear in the listbox.
My first issue & may be more but at present unable to get past this step.
I select a customers name & i see a message Do i wish to delete this customer.
Yes should delete the customer & i should then get the confirmation message, customer is deleted but no confirmation message.
No should stop the process & selct TextBox 1, BUt i see customer has been deleted message followed by customer was not delete message, customer wasnt delete but i see the messages appear

Private Sub ListBox1_Click()
  Dim answer As Integer
  
  Range("A" & ListBox1.List(ListBox1.ListIndex, 1)).Select
  
   Dim c As Range
   With Sheets("DETAILS")
    Set c = .Range("A:A").Find(What:=ListBox1.Value, _
                        After:=.Range("A5"), _
                        LookIn:=xlValues, _
                        LookAt:=xlWhole, _
                        SearchOrder:=xlByRows, _
                        SearchDirection:=xlNext, _
                        MatchCase:=False)
End With
If Not c Is Nothing Then
    If MsgBox("ARE YOU SURE YOU WISH TO DELETE CUSTOMER " & ListBox1.Text & "?", vbYesNo + vbInformation, "DELETE CUSTOMER FROM DATABASE") = vbYes Then
        Rows(c.Row).EntireRow.Delete
        Else:
        TextBox1.Value = ""
        TextBox1.SetFocus
        
        MsgBox "THE CUSTOMER " & Me.ListBox1.Value & " HAS NOW BEEN DELETED" & vbNewLine & "DELETE ANOTHER CUSTOMER ? ", vbYesNo + vbInformation, "CUSTOMER DELETED MESSAGE"
        If Result = vbYes Then
        TextBox1.Value = ""
           Else:
        Unload DeleteCustomer
        Range("A3").Select
        
    
        Unload DeleteCustomer
        MsgBox "THE CUSTOMER " & Me.ListBox1.Value & " WAS NOT DELETED", vbInformation, "CUSTOMER WAS NOT DELETED MEAASGE"
        Range("A3").Select
    End If
Set c = Nothing

      
    End If
    End If
    
End Sub

 

[ipbr21054]

Just an update & im 99% done but with one issue.

Here is the new code now in use.
All the code now does what it should depending on whether the user selected yes or no

The only issue i have is the following message box shown in red below
Selecting Yes clears textbox1 & sets focus on textbox1, this works ok
Selecting No should just unload the DeleteCustomer form & select cell A3 on the worksheet
But what actually happens textbox1 is cleard & userform is still showing

Private Sub ListBox1_Click()
  Dim answer As Integer
  
  Range("A" & ListBox1.List(ListBox1.ListIndex, 1)).Select
  
   Dim c As Range
   With Sheets("DETAILS")
    Set c = .Range("A:A").Find(What:=ListBox1.Value, _
                        After:=.Range("A5"), _
                        LookIn:=xlValues, _
                        LookAt:=xlWhole, _
                        SearchOrder:=xlByRows, _
                        SearchDirection:=xlNext, _
                        MatchCase:=False)
End With
If Not c Is Nothing Then
    Result = MsgBox("ARE YOU SURE YOU WISH TO DELETE CUSTOMER " & ListBox1.Text & "?", vbYesNo + vbCritical, "DELETE CUSTOMER FROM DATABASE")
        If Result = vbYes Then
        Rows(c.Row).EntireRow.Delete
    Else:
        MsgBox "THE CUSTOMER " & Me.ListBox1.Value & " WAS NOT DELETED", vbInformation, "CUSTOMER WAS NOT DELETED MEAASGE"
        TextBox1.Value = ""
        TextBox1.SetFocus
        Exit Sub
    End If
    
       MsgBox "THE CUSTOMER " & Me.ListBox1.Value & " HAS NOW BEEN DELETED" & vbNewLine & vbNewLine & "DO YOU WISH TO DELETE ANOTHER CUSTOMER ? ", vbYesNo + vbInformation, "CUSTOMER DELETED MESSAGE"
        If Result = vbYes Then
        TextBox1.Value = ""
        TextBox1.SetFocus
    Else:
        Unload DeleteCustomer
        Range("A3").Select
        
        

    End If
    End If
    Set c = Nothing
End Sub

 

[dmt32]

Hi,
untested but see if this update to your code does what you want

Private Sub ListBox1_Click()
    Dim answer      As VbMsgBoxResult
    Dim Search      As String
    Dim c           As Range
  
    Search = Me.ListBox1.Value
  
    With ThisWorkbook.Worksheets("DETAILS")
        Set c = .Range("A:A").Find(What:=Search, After:=.Range("A5"), LookIn:=xlValues, LookAt:=xlWhole, _
                                 searchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False)
    End With
  
    If Not c Is Nothing Then
      
        answer = MsgBox("ARE YOU SURE YOU WISH To DELETE CUSTOMER " & Search & "?", vbYesNo + vbInformation, "DELETE CUSTOMER FROM DATABASE")
      
        If answer = vbYes Then
            c.EntireRow.Delete
          
            answer = MsgBox("THE CUSTOMER " & Search & " HAS NOW BEEN DELETED" & vbNewLine & "DELETE ANOTHER CUSTOMER ? ", vbYesNo + vbInformation, "CUSTOMER DELETED MESSAGE")
            If answer = vbNo Then Unload Me Else TextBox1.Value = "": TextBox1.SetFocus
          
        Else
      
            MsgBox "THE CUSTOMER " & Search & " WAS Not DELETED", vbInformation, "CUSTOMER WAS Not DELETED MESSAGE"
          
        End If
      
    End If
  
    Set c = Nothing
  
End Sub

Dave

 

[ipbr21054]

Thanks,
I will take a look once home.

At the bottom of the code i see Set c = Nothing

Can you advise what it actually does.

 

[dmt32]

At the bottom of the code i see Set c = Nothing

Can you advise what it actually does.

As it was in your original code I left it there - what it does is clear the object variable c from memory but as the scope of the variable is procedure level (otherwise known as local ) it is accessible only within your procedure and as soon as the code finishes, the variable will lose its scope i.e the object variable should be nothing once code terminates.
Some coders though like to include a "clean up" for object variables at end of their procedures so does no harm.

Dave