Multiple Sheets to Individual PDFs

[jessi8188]

Hi, I need to print multiple sheets from the same workbook to individual PDFs.

I need it to create a folder on the desktop if possible using cell A1 from the Master sheet which contains the date of payment.
For every sheet in the workbook I want it to save using Name of Sheet & Master!A1
I then want it to activate the Master sheet.

Everything I have tried so far just keeps giving me errors.

Sub ExportToPDFs()
Dim ws As Worksheet
For Each ws In Worksheets
ws.Select
nm = ws.Name
ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, _
Filename:="C:\Users\xo-je\Documents\Fins\" & nm & ".pdf", _
Quality:=xlQualityStandard, IncludeDocProperties:=True, _
IgnorePrintAreas:=False, OpenAfterPublish:=False
Next ws
Sheets("master").Activate
End Sub

 

[Fluff]

Hi & welcome to MrExcel.
How about

Sub jessi()
   Dim Dte As String, Pth As String
   Dim Ws As Worksheet
   
   Dte = Format(Sheets("Master").Range("A1").Value, "dd_mm_yyyy")
   Pth = Environ("userprofile") & "\Desktop\" & Dte & "\"
   If Dir(Pth, vbDirectory) = "" Then
      MkDir Pth
   End If
   For Each Ws In Worksheets
      If LCase(Ws.Name) <> "master" Then
         Ws.ExportAsFixedFormat xlTypePDF, Pth & Ws.Name & " " & Dte & ".pdf", xlQualityStandard, True, False, , , False
      End If
   Next Ws
   Sheets("Master").Activate
End Sub

 

[jessi8188]

Hi & welcome to MrExcel.
How about

Sub jessi()
   Dim Dte As String, Pth As String
   Dim Ws As Worksheet
  
   Dte = Format(Sheets("Master").Range("A1").Value, "dd_mm_yyyy")
   Pth = Environ("userprofile") & "\Desktop\" & Dte & "\"
   If Dir(Pth, vbDirectory) = "" Then
      MkDir Pth
   End If
   For Each Ws In Worksheets
      If LCase(Ws.Name) <> "master" Then
         Ws.ExportAsFixedFormat xlTypePDF, Pth & Ws.Name & " " & Dte & ".pdf", xlQualityStandard, True, False, , , False
      End If
   Next Ws
   Sheets("Master").Activate
End Sub

 

[jessi8188]

Thank you

 

[Fluff]

You're welcome.