need code to delete all rows in active sheet where col "E" does not equal "SJ", "PJ", "CD", or "GJ"

[jdahlke]

still no luck. I have the following: but it deleted all rows that meet my criteria:

Sub Delete()
Dim LastRow As Long
Dim i As Long
Application.ScreenUpdating = False
LastRow = Cells.Find(What:="*", After:=Range("A1"), LookIn:=xlValues, LookAt:= _
xlPart, SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row

For i = LastRow To 2 Step -1
Select Case Cells(i, 5)
Case "SJ", "PJ", "CD", "GJ"
Cells(i, 5).EntireRow.Delete
End Select
Next i

Application.ScreenUpdating = True

End Sub






​

 

[andrewkard]

hello, try:

Sub Delete()
    Dim LastRow As Long
    Dim i As Long
    Application.ScreenUpdating = False
    LastRow = Cells.Find(What:="*", After:=Range("A1"), LookIn:=xlValues, LookAt:= _
                         xlPart, SearchOrder:=xlByRows, SearchDirection:=xlPrevious).Row
    For i = LastRow To 2 Step -1
        Select Case Cells(i, 5).Value
        Case "SJ", "PJ", "CD", "GJ"
        Case Else
            Cells(i, 5).EntireRow.Delete
        End Select
    Next i
    Application.ScreenUpdating = True
End Sub