Need Help creating a VBA for 3 empty fields

[dcme27]

Hello. I have basically no experience creating macros in Excel, but I am looking to make one for cells A2, A3, A4 to show text in the field if the field is empty.

I found one online, but after I paste it in and try and run, it pops up a "Macro" box, but no Macros to select. Below is the data I found online:

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Address = "$B$4" Then
        If Target = "" Then
            ' Cell is empty; mark it and make gray
            Target = "(Customer Name)"
            With Selection.Font
                .ThemeColor = xlThemeColorDark1
                .TintAndShade = -0.249977111117893
            End With
        Else
            ' Cell contains something; remove gray
            With Selection.Font
                .ColorIndex = xlAutomatic
                .TintAndShade = 0
            End With
        End If
    End If
End Sub

 

[Logit]

.
Is this what you were seeking :

Option Explicit

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Target.Address = "$B$4" Then
        If Target.Value = "" Then
            ' Cell is empty; mark it and make gray
            Target.Value = "(Customer Name)"
            With Selection.Font
                .ThemeColor = xlThemeColorDark1
                .TintAndShade = -0.249977111117893
            End With
        Else
            ' Cell contains something; remove gray
            With Selection.Font
                .ColorIndex = xlAutomatic
                .TintAndShade = 0
            End With
        End If
    End If
End Sub

 

[dmt32]

Hi,
try following & see if does what you want

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Me.Range("B2:B4")) Is Nothing Then
    EntryComplete Target
    End If
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Not Intersect(Target, Me.Range("B2:B4")) Is Nothing Then
    EntryComplete Target
    End If
End Sub

Sub EntryComplete(ByVal Target As Range)
    Dim CellText As String
    On Error GoTo exitsub
    
    CellText = Choose(Target.Row - 1, "(Customer Name)", _
                                      "(Employee Number)", _
                                      "(Employee Title)")
    
    Application.EnableEvents = False
        If Target = "" Then
' Cell is empty; mark it and make gray
            Target = CellText
            With Target.Font
                .ThemeColor = xlThemeColorDark1
                .TintAndShade = -0.249977111117893
            End With
        Else
            If Not Target = CellText Then
' Cell contains something; remove gray
            With Target.Font
                .ColorIndex = xlAutomatic
                .TintAndShade = 0
            End With
            End If
        End If
exitsub:
    Application.EnableEvents = True
End Sub

Dave

 

[dcme27]

Thank you... Your code looks great, but I have no idea why I can't get it to actually do anything. Definitely user error on this. I appreciate your help.

 

[dmt32]

Thank you... Your code looks great, but I have no idea why I can't get it to actually do anything. Definitely user error on this. I appreciate your help.

where have you placed the codes? They should be in your worksheets code page.

Dave